Случайный волшебник

С К И Л Л О В А Я С И Б И Р Ь

⛔ Сервер : С К И Л Л О В А Я С И Б И Р Ь Public: 37.230.137.147:27015

© skillpub.ru - 21 янв 2026, 08:38

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 12 ₽

Случайный волшебник

: Random Wizard Player.zip
549.31 КБ; Купить за 300 ₽; Другие ресурсы пользователя Kurtis

Flying Ghosts | Летающие Призраки
Развлекательный плагин.

Copter | Коптер
Коптер с несколькими режимами.

Медик

ДобавилKurtis • 21 ноя 2025, 17:07
АвторKurtis
Версия0.1
Статистика 577 просмотров • 0 комментариев • 1 скачивание

Каждый раунд среди команд выбирается случайный игрок. Этот игрок становится волшебником.
У волшебника заменяется модель ножа на модель волшебной палочки.

Волшебник имеет 2 способности:
1. Атака лучом: при нажатии ЛКМ (если перед вами нет врага для прямой атаки) выпускается луч по направлению прицела, которой в конечной точке наносит урон по врагам в радиусе.
2. Лечение аурой: при нажатии ПКМ (если перед вами нет врага для прямой атаки) в радиусе вокруг вас происходит лечение вас и союзников.

Способности имеют перезарядку и сопровождаются эффектами.

Возможны проблемы при работе с другими плагинами меняющими модель ножа

Исходный код

Код: Выделить всё

#include <amxmodx>
#include <amxmisc>
#include <reapi>
#include <fakemeta_util>
#include <hamsandwich>

#define TASK_PREPARE 11111
#define TASK_DHUD 22222

#define MODEL_WAND_V "models/wizard/v_wand_stock.mdl"
#define MODEL_WAND_P "models/wizard/p_wand.mdl"

#define SPRITE_BEAM "sprites/zbeam1.spr"
#define SPRITE_EXPLOSION "sprites/fexplo1.spr"
#define SOUND_BEAM "wizard/beam.wav"
#define SOUND_EXPLOSION "wizard/explosion.wav"

#define SPRITE_HEALTH "sprites/wizard/heal.spr"
#define SOUND_HEALTH "wizard/heal.wav"

// 1 способность
#define ABILITY_BEAM_RELOAD 15.0 // Перезарядка способности луча
#define ABILITY_BEAM_RADIUS 300.0 // Радиус нанесения урона от способности
#define ABILITY_BEAM_DAMAGE 30.0 // Урон от способности

// 2 способность
#define ABILITY_HEALTH_RELOAD 45.0 // Перезарядка способности лечения
#define ABILITY_HEALTH_RADIUS 500.0 // Радиус лечения
#define ABILITY_HEALTH_ADD 25.0 // Сколько здоровья пополнять
#define ABILITY_HEALTH_MAX 100.0 // Максимальное количество здоровья (чтобы выше не пополнять)

new g_pWizardTe, g_pWizardCt;
new g_iSpriteBeam, g_iSpriteExplosion, g_iSpriteHeal;
new g_eEntityWizard;
new Float: g_flTimeReloadAblityOne[MAX_PLAYERS+1], Float: g_flTimeReloadAblityTwo[MAX_PLAYERS+1];

public plugin_precache() {
	precache_model(MODEL_WAND_V);
	precache_model(MODEL_WAND_P);

	g_iSpriteBeam = precache_model(SPRITE_BEAM);
	g_iSpriteHeal = precache_model(SPRITE_HEALTH);
	g_iSpriteExplosion = precache_model(SPRITE_EXPLOSION);

	precache_sound(SOUND_BEAM);
	precache_sound(SOUND_EXPLOSION);
	precache_sound(SOUND_HEALTH);
}

public client_disconnected(pPlayer) {
	
	remove_task(pPlayer + TASK_DHUD);

	if(g_pWizardTe == pPlayer) {
		g_pWizardTe = -1;
	}

	if(g_pWizardCt == pPlayer) {
		g_pWizardCt = -1;
	}
}

public plugin_init() {
	register_plugin("Random Wizard Player", "0.1", "Kurtis");

	RegisterHookChain(RG_CSGameRules_RestartRound, "CSGameRules_RestartRound_Post", 1);
	RegisterHookChain(RG_CBasePlayerWeapon_DefaultDeploy, "CBasePlayerWeapon_DefaultDeploy_Pre", 0);
	RegisterHookChain(RG_CSGameRules_PlayerSpawn, "CSGameRules_PlayerSpawn_Post", 1);
	RegisterHookChain(RG_CSGameRules_PlayerKilled, "CSGameRules_PlayerKilled_Post", 1);

	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_knife", "fw_PrimaryAttackKnife_Post", 1);
	RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_knife", "fw_SecondaryAttackKnife_Post", 1);

	g_eEntityWizard = rg_create_entity("info_target");

	if(!is_nullent(g_eEntityWizard)) {
		set_entvar(g_eEntityWizard, var_classname, "magic");
	}
}

public CSGameRules_RestartRound_Post() {
	remove_task(g_pWizardTe);
	set_task(0.5, "task_reset_knife_model", g_pWizardTe);

	remove_task(g_pWizardCt);
	set_task(0.5, "task_reset_knife_model", g_pWizardCt);

	remove_task(g_pWizardTe + TASK_DHUD);
	remove_task(g_pWizardCt + TASK_DHUD);

	g_pWizardTe = -1;
	g_pWizardCt = -1;

	remove_task(TASK_PREPARE);

	if(!get_member_game(m_bCompleteReset)) {
		set_task(2.5, "task_prepare", TASK_PREPARE);
	}
}

public task_reset_knife_model(pPlayer) {
	if(is_user_alive(pPlayer)) {
		new iActiveItem = get_member(pPlayer, m_pActiveItem);

		if(is_nullent(iActiveItem)) {
			return;
		}

		ExecuteHamB(Ham_Item_Deploy, iActiveItem);
	}
}

public task_prepare() {
	new iPlayers[MAX_PLAYERS];
	new iCount;

	get_players_ex(iPlayers, iCount,
		GetPlayers_ExcludeDead | GetPlayers_ExcludeBots | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
		"TERRORIST"
	);

	if(iCount > 0) {
		g_pWizardTe = iPlayers[random(iCount)];

		show_wizard_info(g_pWizardTe);
		switch_knife(g_pWizardTe);

		set_task(1.0, "task_show_hud_info", g_pWizardTe + TASK_DHUD, .flags = "b");
	}

	get_players_ex(iPlayers, iCount,
		GetPlayers_ExcludeDead | GetPlayers_ExcludeBots | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
		"CT"
	);

	if(iCount > 0) {
		g_pWizardCt = iPlayers[random(iCount)];

		show_wizard_info(g_pWizardCt);
		switch_knife(g_pWizardCt);

		set_task(1.0, "task_show_hud_info", g_pWizardCt + TASK_DHUD, .flags = "b");
	}
}

public show_wizard_info(pPlayer) {
	set_dhudmessage(0, 255, 185, -1.0, 0.25, .holdtime = 2.0);
	show_dhudmessage(pPlayer, "В этом раунде вы выбраны волшебником!^nВместо ножа волшебная палочка");
}

public task_show_hud_info(pPlayer) {
	pPlayer -= TASK_DHUD;

	static szInfoAbilityOne[128];
	static szInfoAbilityTwo[128];

	new Float: flGameTime = get_gametime();

	if(g_flTimeReloadAblityOne[pPlayer] < flGameTime) {
		format(szInfoAbilityOne, charsmax(szInfoAbilityOne), "Атака лучом (ЛКМ)");
	}
	else {
		format(szInfoAbilityOne, charsmax(szInfoAbilityOne), "Атака лучом: %i сек", floatround(g_flTimeReloadAblityOne[pPlayer] - flGameTime));
	}

	if(g_flTimeReloadAblityTwo[pPlayer] < flGameTime) {
		format(szInfoAbilityTwo, charsmax(szInfoAbilityTwo), "Лечение аурой (ПКМ)");
	}
	else {
		format(szInfoAbilityTwo, charsmax(szInfoAbilityTwo), "Лечение аурой: %i сек", floatround(g_flTimeReloadAblityTwo[pPlayer] - flGameTime));
	}

	set_dhudmessage(165, 74, 255, -1.0, 0.0, .holdtime = 0.7);
	show_dhudmessage(0, "%s^n%s", szInfoAbilityOne, szInfoAbilityTwo);
}

public switch_knife(pPlayer) {
	new iActiveItem = get_member(pPlayer, m_pActiveItem);

	if(is_nullent(iActiveItem) || get_member(iActiveItem, m_iId) != WEAPON_KNIFE) {
		return;
	}

	rg_switch_weapon(pPlayer, iActiveItem);
}

public CBasePlayerWeapon_DefaultDeploy_Pre(iItem, const szViewModel[], const szWeaponModel[], iAnim, const szAnimExt[], skiplocal)
{
	if(!is_nullent(iItem) && get_member(iItem, m_iId) == WEAPON_KNIFE) {
		new pPlayer = get_member(iItem, m_pPlayer);

		if(is_user_alive(pPlayer) && g_pWizardTe == pPlayer || g_pWizardCt == pPlayer) {
			SetHookChainArg(2, ATYPE_STRING, MODEL_WAND_V);
			SetHookChainArg(3, ATYPE_STRING, MODEL_WAND_P);
		}
	}
}

public CSGameRules_PlayerSpawn_Post(pPlayer) {
	if(!is_user_alive(pPlayer)) {
		return;
	}

	remove_task(pPlayer + TASK_DHUD);

	g_flTimeReloadAblityOne[pPlayer] = g_flTimeReloadAblityTwo[pPlayer] = 0.0;
}

public CSGameRules_PlayerKilled_Post(pVictim, pKiller, corpse) {
	if(g_pWizardTe == pVictim) {
		g_pWizardTe = -1;
	}

	if(g_pWizardCt == pVictim) {
		g_pWizardCt = -1;
	}

	remove_task(pVictim + TASK_DHUD);
}

public fw_PrimaryAttackKnife_Post(iWeapon) {
	if(is_nullent(iWeapon)) {
		return;
	}

	new pPlayer = get_member(iWeapon, m_pPlayer);

	if(g_pWizardTe != pPlayer && g_pWizardCt != pPlayer || !is_user_alive(pPlayer)) {
		return;
	}

	static Float: flGameTime; flGameTime = get_gametime();

	if(g_flTimeReloadAblityOne[pPlayer] > flGameTime) {
		return;
	}

	if(is_forward_barrier(pPlayer)) {
		return;
	}

	g_flTimeReloadAblityOne[pPlayer] = flGameTime + ABILITY_BEAM_RELOAD;

	new Float: flVecOriginStart[3];
	get_entvar(iWeapon, var_origin, flVecOriginStart);

	new Float: flVecOriginEnd[3];
	fm_get_aim_origin(pPlayer, flVecOriginEnd);

	new iPlayers[MAX_PLAYERS];
	new iCount;

	switch(get_member(pPlayer, m_iTeam)) {
		case TEAM_TERRORIST: {
			CREATE_BEAMPOINTS(flVecOriginStart, flVecOriginEnd, g_iSpriteBeam, 0, 0, 4, 10, 15, 255, 0, 0, 255, 0, 0);

			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"CT"
			);
		}
		case TEAM_CT: {
			CREATE_BEAMPOINTS(flVecOriginStart, flVecOriginEnd, g_iSpriteBeam, 0, 0, 4, 10, 15, 0, 0, 255, 255, 0, 0);

			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"TERRORIST"
			);
		}
		default: {
			return;
		}
	}

	rh_emit_sound2(iWeapon, 0, CHAN_ITEM, SOUND_BEAM, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
	rh_emit_sound2(0, 0, CHAN_STATIC, SOUND_EXPLOSION, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, flVecOriginEnd);

	CREATE_SPRITE(flVecOriginEnd, g_iSpriteExplosion, 20, 255, 0);

	// rg_dmg_radius(flVecOriginEnd, g_eEntityWizard, pPlayer, ABILITY_BEAM_DAMAGE, ABILITY_BEAM_RADIUS, 0, DMG_ENERGYBEAM);

	for(new i, id; i < iCount; i++) {
		id = iPlayers[i];

		get_entvar(id, var_origin, flVecOriginStart);

		if(get_distance_f(flVecOriginStart, flVecOriginEnd) < ABILITY_BEAM_RADIUS) {
			ExecuteHamB(Ham_TakeDamage, id, g_eEntityWizard, pPlayer, ABILITY_BEAM_DAMAGE, DMG_ENERGYBEAM);
		}
	}
}

public fw_SecondaryAttackKnife_Post(iWeapon) {
	if(is_nullent(iWeapon)) {
		return;
	}

	new pPlayer = get_member(iWeapon, m_pPlayer);

	if(g_pWizardTe != pPlayer && g_pWizardCt != pPlayer || !is_user_alive(pPlayer)) {
		return;
	}

	static Float: flGameTime; flGameTime = get_gametime();

	if(g_flTimeReloadAblityTwo[pPlayer] > flGameTime) {
		return;
	}

	if(is_forward_barrier(pPlayer)) {
		return;
	}

	g_flTimeReloadAblityTwo[pPlayer] = flGameTime + ABILITY_HEALTH_RELOAD;

	new iPlayers[MAX_PLAYERS], iCount, id;
	get_players_ex(iPlayers, iCount, GetPlayers_ExcludeDead);

	new Float: vecOrigin[3];
	get_entvar(pPlayer, var_origin, vecOrigin);

	new iTeam = get_member(pPlayer, m_iTeam);

	for(new i, Float: vecOrigin2[3]; i < iCount; i++) {
		id = iPlayers[i];
		if(get_member(id, m_iTeam) == iTeam) {
			get_entvar(id, var_origin, vecOrigin2);
			
			if(get_distance_f(vecOrigin, vecOrigin2) < ABILITY_HEALTH_RADIUS) {
				set_entvar(id, var_health, floatclamp(Float: get_entvar(id, var_health) + ABILITY_HEALTH_ADD, 1.0, ABILITY_HEALTH_MAX));
			}
		}
	}

	rh_emit_sound2(pPlayer, 0, CHAN_STATIC, SOUND_HEALTH, VOL_NORM, ATTN_NORM, 0, PITCH_NORM/*, 0, vecOrigin*/);
	CREATE_BEAMTORUS(vecOrigin, floatround(ABILITY_HEALTH_RADIUS / 10), g_iSpriteHeal, 0, 0, 15, 2, 2, random_num(200, 255), random_num(200, 255), 0, 255, 0, 0);
}

// thx for msg Retro-kolt Lincoln
stock CREATE_BEAMPOINTS(Float:fStartOrigin[3], Float:fEndOrigin[3], pSprite, iStartFrame = 0, iFrameRate = 0, iLife, iWidth, iAmplitude = 0, iRed, iGreen, iBlue, iBrightness, iScrollSpeed = 0, iReliable = 0) {
	message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMPOINTS);
	write_coord_f(fStartOrigin[0]);
	write_coord_f(fStartOrigin[1]);
	write_coord_f(fStartOrigin[2]);
	write_coord_f(fEndOrigin[0]);
	write_coord_f(fEndOrigin[1]);
	write_coord_f(fEndOrigin[2]);
	write_short(pSprite); // Индекс спрайта из прекеша (index of precached sprite)
	write_byte(iStartFrame);
	write_byte(iFrameRate); // 0.1's
	write_byte(iLife); // 0.1's
	write_byte(iWidth);
	write_byte(iAmplitude); // 0.01's
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	write_byte(iScrollSpeed); // 0.1's
	message_end();
}

stock CREATE_SPRITE(Float:fOrigin[3], pSptite, iWidth, iBrightness, iReliable = 0) {
        engfunc(EngFunc_MessageBegin, iReliable ? MSG_PVS_R : MSG_PVS, SVC_TEMPENTITY, fOrigin, 0);
        write_byte(TE_SPRITE);
        engfunc(EngFunc_WriteCoord, fOrigin[0]);
        engfunc(EngFunc_WriteCoord, fOrigin[1]);
        engfunc(EngFunc_WriteCoord, fOrigin[2]);
        write_short(pSptite); // Индекс спрайта из прекеша (index of precached sprite)
        write_byte(iWidth);
        write_byte(iBrightness);
        message_end();
}
stock CREATE_SPRITETRAIL(Float:fStartOrigin[3], Float:fEndOrigin[3], pSprite, iCount, iLife, iScale, iVelocityAlongVector, iRandomVelocity, iReliable = 0) {
        message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
        write_byte(TE_SPRITETRAIL);
        engfunc(EngFunc_WriteCoord, fStartOrigin[0]);
        engfunc(EngFunc_WriteCoord, fStartOrigin[1]);
        engfunc(EngFunc_WriteCoord, fStartOrigin[2]);
        engfunc(EngFunc_WriteCoord, fEndOrigin[0]);
        engfunc(EngFunc_WriteCoord, fEndOrigin[1]);
        engfunc(EngFunc_WriteCoord, fEndOrigin[2]);
        write_short(pSprite); // Индекс спрайта из прекеша (index of precached sprite)
        write_byte(iCount);
        write_byte(iLife); // 0.1's
        write_byte(iScale);
        write_byte(iVelocityAlongVector); // 10's
        write_byte(iRandomVelocity); // 10's
        message_end(); 
}

stock CREATE_BEAMTORUS(Float:fOrigin[3], iRadius, pSprite, iStartFrame = 0, iFrameRate = 0, iLife, iWidth, iAmplitude = 0, iRed, iGreen, iBlue, iBrightness, iScrollSpeed = 0, iReliable = 0) {
        message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
        write_byte(TE_BEAMTORUS);
        write_coord_f(fOrigin[0]);
        write_coord_f(fOrigin[1]);
        write_coord_f(fOrigin[2]);
        write_coord_f(fOrigin[0]);
        write_coord_f(fOrigin[1]);
        write_coord_f(fOrigin[2] + 16.0 + iRadius * 2);
        write_short(pSprite); // Индекс спрайта из прекеша (index of precached sprite)
        write_byte(iStartFrame);
        write_byte(iFrameRate); // 0.1's
        write_byte(iLife); // 0.1's
        write_byte(iWidth);
        write_byte(iAmplitude); // 0.01's
        write_byte(iRed);
        write_byte(iGreen);
        write_byte(iBlue);
        write_byte(iBrightness);
        write_byte(iScrollSpeed); // 0.1's
        message_end();
}

stock is_forward_barrier(pPlayer) {
	new Float: vecOriginStart[3], Float: vecData[3];

	get_entvar(pPlayer, var_origin, vecOriginStart);
	get_entvar(pPlayer, var_v_angle, vecData);

	vecData[0] = 0.0;

	engfunc(EngFunc_MakeVectors, vecData);
	global_get(glb_v_forward, vecData);

	xs_vec_mul_scalar(vecData, 8192.0, vecData);
	xs_vec_add(vecOriginStart, vecData, vecData);

	engfunc(EngFunc_TraceLine, vecOriginStart, vecData, DONT_IGNORE_MONSTERS, pPlayer, 0);
	get_tr2(0, TR_vecEndPos, vecData);

	return get_distance_f(vecOriginStart, vecData) < 64.0;
}

Версия	Дата выхода	Размер	Скачиваний	Скачать
0.1	21 ноя 2025, 17:00	549.31 КБ	1	Random Wizard Player.zip

Кто сейчас на конференции

Зарегистрированные пользователи: Google [Bot], Semrush [Bot], Дима Попов

С К И Л Л О В А Я С И Б И Р Ь

С К И Л Л О В А Я С И Б И Р Ь+18(STEAM BONUS) Адрес сервера: 37.230.137.147:27015

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 10 ₽

Случайный волшебник

Версия: 0.1 21.11.2025 17:00

Кто сейчас на конференции