Код: Выделить всё

// Модель призрака
#define GHOST_MODEL "models/ghost/ghost.mdl"
// Скорость движения призраков
#define GHOST_SPEED 80.0

// Максимальное количество создаваемых призраков (по стандарту количество спавнов игроков, можно не менять если точек на карте меньше)
const PointsSpawnLimit = 32;

Код: Выделить всё

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <reapi>
#include <xs>

// Модель призрака
#define GHOST_MODEL "models/ghost/ghost.mdl"
// Скорость движения призраков
#define GHOST_SPEED 80.0

const PointsSpawnLimit = 32;
const PointsPathType = 4;

new HamHook: g_hHamSpawnPlayerStart, HamHook: g_hHamSpawnPlayerDeatMatch;
new Array: g_aCellGhost, Array: g_aCellPointStart, Array: g_aCellPointDeathMatch;

public plugin_precache() {
	g_hHamSpawnPlayerStart = RegisterHam(Ham_Spawn, "info_player_start", "fwHam_SpawnPointStart_Post", 1);
	g_hHamSpawnPlayerDeatMatch = RegisterHam(Ham_Spawn, "info_player_deathmatch", "fwHam_SpawnPointDeathMatch_Post", 1);

	g_aCellGhost = ArrayCreate(PointsSpawnLimit);
	g_aCellPointStart = ArrayCreate(PointsSpawnLimit / 2);
	g_aCellPointDeathMatch = ArrayCreate(PointsSpawnLimit / 2);

	precache_model(GHOST_MODEL);
}

public plugin_init() {
	register_plugin("Flying Ghosts", "0.1", "Kurtis");

	DisableHamForward(g_hHamSpawnPlayerStart);
	DisableHamForward(g_hHamSpawnPlayerDeatMatch);

	for(new i, eEnt, ePoint, Float: flVecOriginStart[3], Float: flVecOriginEnd[PointsPathType][3], iCount = ArraySize(g_aCellGhost); i < iCount; i++)
	{
		eEnt = ArrayGetCell(g_aCellGhost, i);

		if(is_nullent(eEnt)) {
			continue;
		}

		switch(get_entvar(eEnt, var_euser2)) {
			case TEAM_TERRORIST: {
				get_entvar(eEnt, var_origin, flVecOriginStart);

				for(new j, Float: flDistance; j < PointsPathType; j++) {
					ePoint = ArrayGetCell(g_aCellPointStart, random(ArraySize(g_aCellPointStart)));

					if(is_nullent(ePoint)) {
						continue;
					}

					get_entvar(ePoint, var_origin, flVecOriginEnd[j]);
					flDistance = get_distance_f(flVecOriginStart, flVecOriginEnd[j]);

					flVecOriginEnd[j][0] += random_float(random_float(-flDistance / 2, -flDistance / 4), random_float(flDistance / 4, flDistance / 2));
					flVecOriginEnd[j][1] += random_float(random_float(-flDistance / 2, -flDistance / 4), random_float(flDistance / 4, flDistance / 2));
					flVecOriginEnd[j][2] += random_float(random_float(-flDistance / 4, -flDistance / 8), random_float(flDistance / 8, flDistance / 4));
				}

				set_entvar(eEnt, var_vuser1, flVecOriginEnd[0]);
				set_entvar(eEnt, var_vuser2, flVecOriginEnd[1]);
				set_entvar(eEnt, var_vuser3, flVecOriginEnd[2]);
				set_entvar(eEnt, var_vuser4, flVecOriginEnd[3]);

				set_entvar(eEnt, var_nextthink, get_gametime() + 1.0);
			}

			case TEAM_CT: {
				get_entvar(eEnt, var_origin, flVecOriginStart);

				for(new j, Float: flDistance; j < PointsPathType; j++) {
					ePoint = ArrayGetCell(g_aCellPointDeathMatch, random(ArraySize(g_aCellPointDeathMatch)));

					if(is_nullent(ePoint)) {
						continue;
					}

					get_entvar(ePoint, var_origin, flVecOriginEnd[j]);
					flDistance = get_distance_f(flVecOriginStart, flVecOriginEnd[j]);

					flVecOriginEnd[j][0] += random_float(random_float(-flDistance / 2, -flDistance / 4), random_float(flDistance / 4, flDistance / 2));
					flVecOriginEnd[j][1] += random_float(random_float(-flDistance / 2, -flDistance / 4), random_float(flDistance / 4, flDistance / 2));
					flVecOriginEnd[j][2] += random_float(random_float(-flDistance / 4, -flDistance / 8), random_float(flDistance / 8, flDistance / 4));
				}

				set_entvar(eEnt, var_vuser1, flVecOriginEnd[0]);
				set_entvar(eEnt, var_vuser2, flVecOriginEnd[1]);
				set_entvar(eEnt, var_vuser3, flVecOriginEnd[2]);
				set_entvar(eEnt, var_vuser4, flVecOriginEnd[3]);

				set_entvar(eEnt, var_nextthink, get_gametime() + 1.0);
			}
		}
	}
}

public fwHam_SpawnPointStart_Post(eEnt) {
	if(!is_nullent(eEnt)) {
		static i;
		if(i >= (PointsSpawnLimit / 2)) {
			return;
		}
		i++;

		ArrayPushCell(g_aCellPointStart, eEnt);

		new Float: flVecOrigin[3];
		get_entvar(eEnt, var_origin, flVecOrigin);

		_create_ghost(flVecOrigin, TEAM_CT);
	}
}

public fwHam_SpawnPointDeathMatch_Post(eEnt) {
	if(!is_nullent(eEnt)) {
		static i;
		if(i >= (PointsSpawnLimit / 2)) {
			return;
		}
		i++;

		ArrayPushCell(g_aCellPointDeathMatch, eEnt);

		new Float: flVecOrigin[3];
		get_entvar(eEnt, var_origin, flVecOrigin);

		_create_ghost(flVecOrigin, TEAM_TERRORIST);
	}
}

public _create_ghost(Float: flVecOriginStart[3], TeamName: iTeam) {
	new eEnt = rg_create_entity("info_target");

	if(!is_nullent(eEnt)) {
		engfunc(EngFunc_SetModel, eEnt, GHOST_MODEL);
		engfunc(EngFunc_SetOrigin, eEnt, flVecOriginStart);

		set_entvar(eEnt, var_classname, "ghost");
		set_entvar(eEnt, var_solid, SOLID_TRIGGER);
		set_entvar(eEnt, var_movetype, MOVETYPE_NOCLIP);
		set_entvar(eEnt, var_euser1, random(PointsPathType));
		set_entvar(eEnt, var_euser2, iTeam);

		SetThink(eEnt, "_think_ghost");

		ArrayPushCell(g_aCellGhost, eEnt);
	}
}

public _think_ghost(eEnt) {
	if(is_nullent(eEnt)) {
		return;
	}

	set_entvar(eEnt, var_nextthink, get_gametime() + 1.0);

	new Float: flVecOriginStart[3], Float: flVecOriginEnd[3], Float: flVecVelocity[3];
	get_entvar(eEnt, var_origin, flVecOriginStart);

	switch(get_entvar(eEnt, var_euser1))
	{
		case 0: {
			get_entvar(eEnt, var_vuser1, flVecOriginEnd);
		}

		case 1: {
			get_entvar(eEnt, var_vuser2, flVecOriginEnd);
		}

		case 2: {
			get_entvar(eEnt, var_vuser3, flVecOriginEnd);
		}

		case 3: {
			get_entvar(eEnt, var_vuser4, flVecOriginEnd);
		}
	}

	new Float: flDistance = get_distance_f(flVecOriginStart, flVecOriginEnd);

	if(flDistance < 50.0) {
		set_entvar(eEnt, var_euser1, random(PointsPathType));
	}

	xs_vec_sub(flVecOriginEnd, flVecOriginStart, flVecVelocity);
	xs_vec_div_scalar(flVecVelocity, flDistance / GHOST_SPEED, flVecVelocity);
	set_entvar(eEnt, var_velocity, flVecVelocity);

	new Float: flAngles[3];
	vector_to_angle(flVecVelocity, flAngles);
	set_entvar(eEnt, var_angles, flAngles);
}

Код: Выделить всё

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <reapi>
#include <xs>