Код: Выделить всё

#include <amxmodx>
#include <amxmisc>
#include <reapi>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

// Максимум NPC на карте
const SnowManNPC_CountMax = 32;
// Здоровье NPC
const Float: SnowManNpc_Health = 500.0;
// Скорость NPC
const Float: SnowManNpc_Speed = 300.0;
// Урон от снежка NPC
const Float: SnowBall_Damage = 30.0;

// Модель NPC
new const SnowManNpc_Model[] = "models/snowman/npc_snowman.mdl";
// Модель снежка
new const SnowBall_Model[] = "models/snowman/snowball.mdl";

// Звук спавна NPC
new const SnowManNpc_SoundSpawn[] = "snowman/spawn.wav";
// Звук получения урона NPC
new const SnowManNpc_SoundHit[] = "snowman/hit.wav";
// Звук броска снежка
new const SnowBall_SoundThrow[] = "snowman/splash.wav";

const SnowManNpc_Impulse = 10612;
const SnowBall_Impulse = 14213;

new Array: g_aCellSpot;
new g_iSpriteTrail;
new g_iFwdSnowmanKilled;

public plugin_precache() {
	new szMapName[16];
	get_mapname(szMapName, charsmax(szMapName));

	if(!equal(szMapName, "mode_snowgame")) {
		set_fail_state("Плагин отключён. Работает только на карте `mode_snowgame`");
	}

	_load_config_to_pause_plugins();

	precache_model(SnowManNpc_Model);
	precache_model(SnowBall_Model);

	precache_sound(SnowManNpc_SoundSpawn);
	precache_sound(SnowManNpc_SoundHit);
	precache_sound(SnowBall_SoundThrow);

	g_iSpriteTrail = precache_model("sprites/zbeam3.spr");
}

public plugin_init()
{
	register_plugin("Mode: Game SnowMans", "0.1", "Kurtis");

	RegisterHookChain(RG_CSGameRules_RestartRound, "CSGameRules_RestartRound_Post", 1);
	RegisterHookChain(RG_CSGameRules_PlayerSpawn, "CSGameRules_PlayerSpawn_Post", 1);
	RegisterHookChain(RG_CSGameRules_PlayerKilled, "CSGameRules_PlayerKilled_Post", 1);
	RegisterHookChain(RG_CBasePlayer_TakeDamage, "CBasePlayer_TakeDamage_Pre");

	RegisterHam(Ham_TakeDamage, "info_target", "Ham_SnowManNpc_TakeDamage_Pre"); 
	RegisterHam(Ham_Killed, "info_target", "Ham_SnowManNpc_Killed_Pre"); 

	g_aCellSpot = ArrayCreate(1);

	g_iFwdSnowmanKilled = CreateMultiForward("snowman_killed", ET_IGNORE, FP_CELL);

	_get_spots();
}

public client_disconnected(pPlayer) {
	RequestFrame("_check_count");
}

public CSGameRules_RestartRound_Post() {
	_clear_snowmans();

	if(!get_member_game(m_bCompleteReset)) {
		set_task(3.0, "_check_count");
	}
}

public CSGameRules_PlayerSpawn_Post(pPlayer) {
	if(!is_user_alive(pPlayer))
		return;

	RequestFrame("_check_count");
}

public CSGameRules_PlayerKilled_Post(pVictim, pKiller, iCorpse) {
	if(!is_user_connected(pVictim))
		return;

	set_member(pVictim, m_flRespawnPending, get_gametime() + 3.0);
}

public CBasePlayer_TakeDamage_Pre(pVictim, eInflictor, pAttacker, Float: flDamage, bitDamageType) {
	if(is_user_connected(pVictim) && is_user_connected(pAttacker)) {
		SetHookChainReturn(ATYPE_INTEGER, 0);
		return HC_SUPERCEDE;
	}

	return HC_CONTINUE;
}

public Ham_SnowManNpc_TakeDamage_Pre(eEnt, eInflictor, pKiller, Float: flDamage, bitDamageType) {
	if(is_nullent(eEnt)) {
		return;
	}

	rh_emit_sound2(eEnt, 0, CHAN_STATIC, SnowManNpc_SoundHit, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, NULL_VECTOR);
	_play_ent_animation(eEnt, 5, 1.0, 1.0);
}

public Ham_SnowManNpc_Killed_Pre(eEnt, pKiller, iCorpse) {
	if(is_nullent(eEnt)) {
		return HAM_IGNORED;
	}

	if(is_user_connected(pKiller)) {
		ExecuteForward(g_iFwdSnowmanKilled, _, pKiller);
	}

	_play_ent_animation(eEnt, 7, 1.0, 1.0);

	set_entvar(eEnt, var_velocity, NULL_VECTOR);
	set_entvar(eEnt, var_solid, SOLID_NOT);
	set_entvar(eEnt, var_movetype, MOVETYPE_NOCLIP);
	set_entvar(eEnt, var_takedamage, DAMAGE_NO);

	SetThink(eEnt, "");
	SetTouch(eEnt, "");

	set_entvar(eEnt, var_nextthink, get_gametime());

	set_task(3.0, "_remove_snowman", eEnt);

	return HAM_SUPERCEDE;
}

public _remove_snowman(eEnt) {
	if(is_nullent(eEnt)) {
		return;
	}

	_remove_ent(eEnt);
	RequestFrame("_check_count");
}

public _create_snowman() {
	new eSpot = ArrayGetCell(g_aCellSpot, random(ArraySize(g_aCellSpot)))

	if(is_nullent(eSpot)) {
		return;
	}

	new eEnt = rg_create_entity("info_target");

	if(is_nullent(eEnt)) {
		return;
	}

	new Float: flVecOrigin[3];
	get_entvar(eSpot, var_origin, flVecOrigin);

	engfunc(EngFunc_SetModel, eEnt, SnowManNpc_Model);
	engfunc(EngFunc_SetOrigin, eEnt, flVecOrigin);
	engfunc(EngFunc_SetSize, eEnt, Float: { -10.0, -10.0, -34.0 }, { 10.0, 10.0, 8.0 });

	set_entvar(eEnt, var_classname, "npc_snowman");
	set_entvar(eEnt, var_solid, SOLID_BBOX);
	set_entvar(eEnt, var_movetype, MOVETYPE_PUSHSTEP);
	set_entvar(eEnt, var_takedamage, DAMAGE_YES);
	set_entvar(eEnt, var_health, SnowManNpc_Health);
	set_entvar(eEnt, var_gravity, 10.0);
	set_entvar(eEnt, var_impulse, SnowManNpc_Impulse);
	set_entvar(eEnt, var_euser1, NULLENT);
	set_entvar(eEnt, var_fuser1, 0.0);

	SetTouch(eEnt, "_snowman_touch");

	_play_ent_animation(eEnt, 1, 1.0, 1.0);

	new Float: flGameTime = get_gametime();
	static Float: flNextTime;

	if(flNextTime < flGameTime) {
		rg_send_audio(0, SnowManNpc_SoundSpawn);
		flNextTime = flGameTime + 2.0;
	}
}

public _snowman_touch(eEnt, eOther) {
	if(is_nullent(eEnt)) {
		return;
	}

	SetTouch(eEnt, "");
	SetThink(eEnt, "_snowman_think");
	set_entvar(eEnt, var_nextthink, get_gametime() + 0.1);
}

public _snowman_think(eEnt) {
	new Float: flVecOriginNpc[3];
	get_entvar(eEnt, var_origin, flVecOriginNpc);

	new pVictim = get_entvar(eEnt, var_euser1);
	new Float: flVecOriginVictim[3];

	if(is_user_alive(pVictim)) {
		get_entvar(pVictim, var_origin, flVecOriginVictim);
		flVecOriginVictim[2] += 8.0;

		if(!_is_origins_obstacle(flVecOriginNpc, flVecOriginVictim, eEnt, pVictim)) {
			set_entvar(eEnt, var_euser1, pVictim);

			new Float: flDistance = get_distance_f(flVecOriginNpc, flVecOriginVictim);

			new Float: flVecVelocity[3];
			xs_vec_sub(flVecOriginVictim, flVecOriginNpc, flVecVelocity);

			if(flDistance < 30.0) {
				_play_ent_animation(eEnt, 0, 1.0, 1.0);
				xs_vec_div_scalar(flVecVelocity, 1.0, flVecVelocity);

				ExecuteHamB(Ham_Killed, pVictim, eEnt, 1);
			}
			else {
				new Float: flGameTime = get_gametime();

				if(Float: get_entvar(eEnt, var_fuser1) < flGameTime) {
					set_entvar(eEnt, var_fuser1, flGameTime + 0.5);
					_create_snowball(eEnt, pVictim, flVecOriginNpc, flVecOriginVictim);
				}

				_play_ent_animation(eEnt, 2, 1.0, 1.0);
				xs_vec_div_scalar(flVecVelocity, flDistance / SnowManNpc_Speed, flVecVelocity);
			}

			set_entvar(eEnt, var_velocity, flVecVelocity);

			new Float: flVecAngles[3];
			vector_to_angle(flVecVelocity, flVecAngles);
			flVecAngles[0] = flVecAngles[2] = 0.0;
			set_entvar(eEnt, var_angles, flVecAngles);
		}
		else {
			_play_ent_animation(eEnt, 1, 1.0, 1.0);
		}
	}
	else {
		new iPlayers[MAX_PLAYERS], iCountPlayers;
		get_players_ex(iPlayers, iCountPlayers, GetPlayers_ExcludeDead);

		for(new i; i < 10; i++) { // ~ N
			pVictim = iPlayers[random_num(0, iCountPlayers-1)];

			get_entvar(pVictim, var_origin, flVecOriginVictim);
			flVecOriginVictim[2] += 8.0;

			if(!_is_origins_obstacle(flVecOriginNpc, flVecOriginVictim, eEnt, pVictim)) {
				set_entvar(eEnt, var_euser1, pVictim);
				break;
			}
		}
	}

	set_entvar(eEnt, var_nextthink, get_gametime() + 0.1);
}

public _create_snowball(eEnt, pVictim, Float: flVecOriginStart[3], Float: flVecOriginEnd[3]) {
	new eSnowBall = rg_create_entity("info_target");

	if(is_nullent(eSnowBall)) {
		return;
	}

	engfunc(EngFunc_SetModel, eSnowBall, SnowBall_Model);
	engfunc(EngFunc_SetOrigin, eSnowBall, flVecOriginStart);
	engfunc(EngFunc_SetSize, eSnowBall, Float: { -5.0, -5.0, -5.0 }, { 5.0, 5.0, 5.0 });

	set_entvar(eSnowBall, var_classname, "snowball");
	set_entvar(eSnowBall, var_solid, SOLID_TRIGGER);
	set_entvar(eSnowBall, var_movetype, MOVETYPE_FLY);
	set_entvar(eSnowBall, var_impulse, SnowBall_Impulse);
	set_entvar(eSnowBall, var_nextthink, get_gametime() + 10.0);
	set_entvar(eSnowBall, var_owner, eEnt);

	SetThink(eSnowBall, "_snowball_think");
	SetTouch(eSnowBall, "_snowball_touch");

	_play_ent_animation(eSnowBall, 1, 1.0, 1.0);

	new Float: flVecVelocity[3];
	xs_vec_sub(flVecOriginEnd, flVecOriginStart, flVecVelocity);
	xs_vec_div_scalar(flVecVelocity, get_distance_f(flVecOriginEnd, flVecOriginStart) / 1500.0, flVecVelocity);
	set_entvar(eSnowBall, var_velocity, flVecVelocity);

	rh_emit_sound2(eSnowBall, 0, CHAN_STATIC, SnowBall_SoundThrow, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, flVecOriginStart);
	CREATE_BEAMFOLLOW(eSnowBall, g_iSpriteTrail, 5, 2, 153, 217, 234, 255, 0);
}

public _snowball_think(eSnowBall) {
	_remove_ent(eSnowBall);
}

public _snowball_touch(eSnowBall, eOther) {
	if(is_nullent(eSnowBall)) {
		return;
	}

	if(!is_nullent(eOther)) {
		new iImpulse = get_entvar(eOther, var_impulse);
		if(iImpulse == SnowManNpc_Impulse || iImpulse == SnowBall_Impulse) {
			return;
		}

		if(is_user_alive(eOther)) {
			ExecuteHamB(Ham_TakeDamage, eOther, eSnowBall, eSnowBall, SnowBall_Damage, DMG_FREEZE);
		}
	}

	_remove_ent(eSnowBall);
}

public _get_spots() {
	new eEnt = NULLENT;
	new szName[6];
	while((eEnt = rg_find_ent_by_class(eEnt, "info_target")) > 0) {
		if(is_nullent(eEnt)) {
			continue;
		}

		get_entvar(eEnt, var_targetname, szName, charsmax(szName));

		if(equal(szName, "spawn", charsmax(szName))) {
			ArrayPushCell(g_aCellSpot, eEnt);
		}
	}
}

public _check_count() {
	new iAlivePlayersCount;

	for(new id = 1; id <= MaxClients; id++) {
		if(!is_user_alive(id)) {
			continue;
		}

		switch(get_member(id, m_iTeam)) {
			case TEAM_TERRORIST: {
				iAlivePlayersCount++;
			}

			case TEAM_CT: {
				iAlivePlayersCount++;
			}
		}
	}

	new iSnowMansCount;
	new eEnt = NULLENT;
	while((eEnt = rg_find_ent_by_class(eEnt, "npc_snowman")) > 0) {
		if(is_nullent(eEnt) || get_entvar(eEnt, var_impulse) != SnowManNpc_Impulse) {
			continue;
		}

		iSnowMansCount++;
	}

	while(iSnowMansCount < iAlivePlayersCount) {
		_create_snowman();
		iSnowMansCount++;
	}
}

public _clear_snowmans() {
	new eEnt = NULLENT;
	while((eEnt = rg_find_ent_by_class(eEnt, "npc_snowman")) > 0) {
		if(is_nullent(eEnt) || get_entvar(eEnt, var_impulse) != SnowManNpc_Impulse) {
			continue;
		}

		_remove_ent(eEnt);
	}
}

public _play_ent_animation(eEnt, iSequence, Float: flAnimTime, Float: flFrameRate) {
	set_entvar(eEnt, var_sequence, iSequence);
	set_entvar(eEnt, var_animtime, flAnimTime);
	set_entvar(eEnt, var_framerate, flFrameRate);
}

public _is_origins_obstacle(Float: flVecOriginStart[3], Float: flVecOriginEnd[3], eEnt, pHit) {
	engfunc(EngFunc_TraceLine, flVecOriginStart, flVecOriginEnd, DONT_IGNORE_MONSTERS, eEnt, 0);

	return !(get_tr2(0, TR_pHit) == pHit);
}

public _remove_ent(eEnt) {
	if(!is_nullent(eEnt)) {
		SetThink(eEnt, "");
		SetTouch(eEnt, "");

		set_entvar(eEnt, var_nextthink, get_gametime());
		rg_remove_entity(eEnt);
	}
}

public _load_config_to_pause_plugins() {
	new const szConfigPath[] = "addons/amxmodx/configs/mode_snowgame_plugins_pause.cfg";

	if(!file_exists(szConfigPath)) {
		return;
	}

	new INIParser: iParser = INI_CreateParser();

	INI_SetReaders(iParser, "INI_ReadKeyValue");
	INI_ParseFile(iParser, szConfigPath);

	INI_DestroyParser(iParser);
}

public bool: INI_ReadKeyValue(INIParser: iParser, const szKey[], const szValue[]) {
	if(szKey[0] == EOS) {
		return true;
	}

	new szString[128];
	format(szString, charsmax(szString), "%s", szKey);
	trim(szString);

	if(contain(szString, ".amxx")) {
		pause("ac", szString);
	}

	return true;
}

// thx Retro-Colt Lincoln
stock CREATE_BEAMFOLLOW(iEntity, pSptite, iLife, iWidth, iRed, iGreen, iBlue, iBrightness, iReliable = 0)
{
	message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMFOLLOW);
	write_short(iEntity);
	write_short(pSptite);
	write_byte(iLife); // 0.1's
	write_byte(iWidth);
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	message_end();
}

Код: Выделить всё

#include <amxmodx>
#include <reapi>
#include <fakemeta_util>
#include <hamsandwich>
#include <xs>

new const ItemWeaponBaseName[] = "weapon_galil";
const WeaponIdType: ItemWeaponBaseBaseType = WEAPON_GALIL;
const ItemWeaponImpulse = 76146;
new const ItemWeaponWeaponList[] = "snow_game/weapon_ethereal";
//
new const ItemWeaponModelV[] = "models/snow_game/v_ethereal.mdl";
new const ItemWeaponModelP[] = "models/snow_game/p_ethereal.mdl";
new const ItemWeaponSoundShot[] = "weapons/ethereal-1.wav";
new const ItemWeaponSoundDraw[] = "weapons/ethereal_draw.wav";
new const ItemWeaponSoundReload[] = "weapons/ethereal_reload.wav";
//
const ItemWeaponEtherealAmmo = 50;
const ItemWeaponEtherealMaxAmmo = 9999;
const Float: ItemWeaponEtherealDamage = 30.0;

new g_iMsgWeaponList;

public plugin_precache() {
	new szMapName[16];
	get_mapname(szMapName, charsmax(szMapName));

	if(!equal(szMapName, "mode_snowgame")) {
		set_fail_state("Плагин отключён. Работает только на карте `mode_snowgame`");
	}

	precache_model(ItemWeaponModelV);
	precache_model(ItemWeaponModelP);

	precache_sound(ItemWeaponSoundShot);
	precache_sound(ItemWeaponSoundDraw);
	precache_sound(ItemWeaponSoundReload);

	precache_generic(fmt("sprites/%s.txt", ItemWeaponWeaponList));
	precache_generic("sprites/snow_game/640hud7.spr");
	precache_generic("sprites/snow_game/640hud74.spr");
}

public plugin_init()
{
	register_plugin("Winter Weapon Ethereal", "0.1", "Kurtis")

	RegisterHookChain(RG_CSGameRules_PlayerSpawn, "CSGameRules_PlayerSpawn_Post", 1);
	RegisterHookChain(RG_CBasePlayerWeapon_DefaultDeploy, "CBasePlayerWeapon_DefaultDeploy_Pre");
	RegisterHookChain(RG_CBasePlayer_DropPlayerItem, "CBasePlayer_DropPlayerItem_Pre");
	RegisterHookChain(RG_CWeaponBox_SetModel, "CWeaponBox_SetModel_Post", 1);

	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1);
	register_forward(FM_PlaybackEvent, "fw_PlaybackEvent_Pre");

	RegisterHam(Ham_Weapon_PrimaryAttack, ItemWeaponBaseName, "Ham_Weapon_PrimaryAttack_Post", 1);

	register_clcmd(ItemWeaponWeaponList, "Clcmd_WeaponSwitch");

	g_iMsgWeaponList = get_user_msgid("WeaponList");
}

public CSGameRules_PlayerSpawn_Post(pPlayer) {
	if(!is_user_alive(pPlayer)) {
		return;
	}

	_give_weapon(pPlayer);
}

public CBasePlayerWeapon_DefaultDeploy_Pre(iItem, const szViewModel[], const szWeaponModel[], iAnim, const szAnimExt[], skiplocal) {
	if(is_nullent(iItem) || get_entvar(iItem, var_impulse) != ItemWeaponImpulse) {
		return;
	}

	SetHookChainArg(2, ATYPE_STRING, ItemWeaponModelV);
	SetHookChainArg(3, ATYPE_STRING, ItemWeaponModelP);
}

public CBasePlayer_DropPlayerItem_Pre(pPlayer, const szItemName[]) {
	SetHookChainReturn(ATYPE_INTEGER, 0);
	return HC_SUPERCEDE;
}

public CWeaponBox_SetModel_Post(eEnt, const szModelName[]) {
	if(!is_nullent(eEnt)) {
		SetThink(eEnt, "");
		SetTouch(eEnt, "");

		set_entvar(eEnt, var_nextthink, get_gametime());
		rg_remove_entity(eEnt);
	}
}

public fw_UpdateClientData_Post(pPlayer, SendWeapons, CD_Handle) {
	if(!is_user_connected(pPlayer)){
		return;
	}

	new iItem = get_member(pPlayer, m_pActiveItem);

	if(is_nullent(iItem) || get_entvar(iItem, var_impulse) != ItemWeaponImpulse) {
		return;
	}

	set_cd(CD_Handle, CD_flNextAttack, get_gametime () + 0.001);
} 

public fw_PlaybackEvent_Pre(iFlags, pPlayer)
{
	if(!is_user_connected(pPlayer)){
		return FMRES_IGNORED;
	}

	new iItem = get_member(pPlayer, m_pActiveItem);

	if(is_nullent(iItem) || get_entvar(iItem, var_impulse) != ItemWeaponImpulse) {
		return FMRES_IGNORED;
	}

	return FMRES_SUPERCEDE;
}

public Ham_Weapon_PrimaryAttack_Post(iItem) {
	if(is_nullent(iItem) || get_entvar(iItem, var_impulse) != ItemWeaponImpulse) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_connected(pPlayer) || !rg_get_user_ammo(pPlayer, ItemWeaponBaseBaseType)) {
		return;
	}

	new Float: flVecOriginStart[3];
	GetBonePosition(pPlayer, 31, flVecOriginStart); // левша 16

	new Float: flVecOriginEnd[3];
	fm_get_aim_origin(pPlayer, flVecOriginEnd);

	new Float: flVecVelocity[3];
	xs_vec_sub(flVecOriginEnd, flVecOriginStart, flVecVelocity);
	xs_vec_div_scalar(flVecVelocity, get_distance_f(flVecOriginEnd, flVecOriginStart) / 1500.0, flVecVelocity);

	CREATE_USERTRACER(pPlayer, flVecOriginStart, flVecVelocity, 20, 7, 5);
	rh_emit_sound2(iItem, 0, CHAN_WEAPON, ItemWeaponSoundShot, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, NULL_VECTOR);
}

public _give_weapon(pPlayer) {
	new iItem = rg_give_custom_item(pPlayer, ItemWeaponBaseName, GT_REPLACE, ItemWeaponImpulse);

	if(!is_nullent(iItem)) {
		set_member(iItem, m_Weapon_iDefaultAmmo, ItemWeaponEtherealAmmo);
		rg_set_iteminfo(iItem, ItemInfo_iMaxClip, ItemWeaponEtherealAmmo);
		rg_set_user_ammo(pPlayer, ItemWeaponBaseBaseType, ItemWeaponEtherealAmmo);

		rg_set_iteminfo(iItem, ItemInfo_iMaxAmmo1, ItemWeaponEtherealMaxAmmo);
		rg_set_user_bpammo(pPlayer, ItemWeaponBaseBaseType, ItemWeaponEtherealMaxAmmo);

		set_member(iItem, m_Weapon_flBaseDamage, ItemWeaponEtherealDamage);

		// https://wiki.alliedmods.net/CS_WeaponList_Message_Dump
		MSG_WEAPONLIST(pPlayer, ItemWeaponWeaponList, 4, 90, -1, -1, 0, 17, ItemWeaponBaseBaseType, ITEM_FLAG_SELECTONEMPTY);
	}
}

public Clcmd_WeaponSwitch(pPlayer) {
	engclient_cmd(pPlayer, ItemWeaponBaseName);
	return PLUGIN_HANDLED;
}

stock MSG_WEAPONLIST(pPlayer, const sWeaponName[], iPrimaryAmmoID, iPrimaryAmmoMax, iSecondaryAmmoID, iSecondaryAmmoMax, iSlotID, iNumberInSlotID, any: iWeaponID, iFlags)
{
	message_begin(pPlayer ? MSG_ONE : MSG_INIT, g_iMsgWeaponList, .player = pPlayer);
	write_string(sWeaponName);
	write_byte(iPrimaryAmmoID);
	write_byte(iPrimaryAmmoMax);
	write_byte(iSecondaryAmmoID);
	write_byte(iSecondaryAmmoMax);
	write_byte(iSlotID);
	write_byte(iNumberInSlotID);
	write_byte(iWeaponID);
	write_byte(iFlags);
	message_end();
}

stock CREATE_USERTRACER(pPlayer, Float: flVecOrigin[3], Float: flVecVelocity[3], iLife, iColor, iLength)
{
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY, .player = pPlayer);
	write_byte(TE_USERTRACER);
	write_coord_f(flVecOrigin[0]);
	write_coord_f(flVecOrigin[1]);
	write_coord_f(flVecOrigin[2]);
	write_coord_f(flVecVelocity[0]);
	write_coord_f(flVecVelocity[1]);
	write_coord_f(flVecVelocity[2]);
	write_byte(iLife);
	write_byte(iColor);
	write_byte(iLength);
	message_end();
}