Deagle Sniper

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 12 ₽

: Deagle Sniper.zip
3.02 MБ; Другие ресурсы пользователя Kurtis

Last Stand (второе дыхание)
Механика второго шанса при убийстве

ClayMore
Добавляет на сервер ClayMore

Smoke Toxic Gas
Добавление эффекта токсичности для дыма.

Grenade Trajectory
Траектории полёта гранат

ZP Human Classes
Классы людей для ZP 4.3

ДобавилKurtis • 02 авг 2026, 14:15
АвторKurtis
Версия0.1
Статистика 5517 просмотров • 0 комментариев • 8 скачиваний

Замена стандартного дигла на снайперский дигл.

1. Учитывается щит: отдельная модель с щитом и без, а также невозможно зайти в зум с щитом (если у кого-то ещё вообще используются щиты на сервере).
2. Примерная логика поведения как у оружий с зумом.
3. Режим зума: как первое приближение у АВП.
4. Уменьшенный разброс в зуме.
5. Пониженная скорость в зуме.
6. Кастомный звук выстрела (возможно минус, так как пришлось "интерполировать предикцию").

Изображения

Исходный код

Код: Выделить всё

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>
#include <fakemeta>
#include <reapi>

new const g_szVerionPlugin[] = "0.1";
//
new const g_szDeagleModel_View[] = "models/deagle_sniper/v_deagle.mdl";
new const g_szDeagleModel_Player[] = "models/deagle_sniper/p_deagle.mdl";
new const g_szDeagleModel_Weapon[] = "models/deagle_sniper/w_deagle.mdl";
//
new const g_szDeagleModel_WeaponOld[] = "models/w_deagle.mdl";

new const g_szDeagleModelWithShield_View[] = "models/deagle_sniper/v_shield_deagle.mdl";
new const g_szDeagleModelWithShield_Player[] = "models/deagle_sniper/p_shield_deagle.mdl";

new const g_szZoomSound[] = "weapons/zoom.wav";
//
new const g_szCustomShotSound[] = "deagle_sniper/deagle-1.wav";

new Float: g_flLastShotTime[MAX_PLAYERS+1];

public plugin_precache() {
	precache_model(g_szDeagleModel_View);
	precache_model(g_szDeagleModel_Player);
	precache_model(g_szDeagleModel_Weapon);

	precache_model(g_szDeagleModelWithShield_View);
	precache_model(g_szDeagleModelWithShield_Player);

	precache_sound(g_szZoomSound);
	precache_sound(g_szCustomShotSound);
}

public plugin_init() {
	register_plugin("Deagle Sniper", g_szVerionPlugin, "Kurtis");

	RegisterHookChain(RG_CBasePlayerWeapon_DefaultDeploy, "CBasePlayerWeapon_DefaultDeploy_Pre");
	RegisterHookChain(RG_CBasePlayer_ResetMaxSpeed, "CBasePlayer_ResetMaxSpeed_Post", 1);

	RegisterHam(Ham_Item_PostFrame, "weapon_deagle", "CBasePlayerWeapon_PostFrame_Pre");
	RegisterHam(Ham_Weapon_Reload, "weapon_deagle", "RG_CBasePlayerWeapon_Reload_Post", 1);
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_deagle", "RG_CBasePlayerWeapon_PrimaryAttack_Post", 1);

	register_forward(FM_SetModel, "fw_SetModel_Pre");
	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1);
	register_forward(FM_PlaybackEvent, "fw_PlaybackEvent_Pre");
}

public CBasePlayerWeapon_DefaultDeploy_Pre(iItem, const szViewModel[], const szWeaponModel[], iAnim, const szAnimExt[], skiplocal) {
	if(is_nullent(iItem) || get_member(iItem, m_iId) != WEAPON_DEAGLE) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_connected(pPlayer)) {
		return;
	}

	g_flLastShotTime[pPlayer] = 0.0;

	if(get_member(pPlayer, m_bOwnsShield)) {
		SetHookChainArg(2, ATYPE_STRING, g_szDeagleModelWithShield_View);
		SetHookChainArg(3, ATYPE_STRING, g_szDeagleModelWithShield_Player);
	}
	else {
		SetHookChainArg(2, ATYPE_STRING, g_szDeagleModel_View);
		SetHookChainArg(3, ATYPE_STRING, g_szDeagleModel_Player);
	}
}

public CBasePlayer_ResetMaxSpeed_Post(pPlayer) {
	if(!is_user_connected(pPlayer)) {
		return;
	}

	new iItem = get_member(pPlayer, m_pActiveItem);

	if(is_nullent(iItem) || get_member(iItem, m_iId) != WEAPON_DEAGLE) {
		return;
	}

	if(cs_get_user_zoom(pPlayer) == CS_SET_FIRST_ZOOM) {
		// Максимальная скорость в режиме зума
		const Float: flMaxSpeedInZoom = 150.0;

		set_entvar(pPlayer, var_maxspeed, flMaxSpeedInZoom);
	}
}

public CBasePlayerWeapon_PostFrame_Pre(iItem) {
	if(is_nullent(iItem)) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_connected(pPlayer) || get_member(pPlayer, m_bOwnsShield)) {
		return;
	}

	if(get_entvar(pPlayer, var_button) & IN_ATTACK2 && Float: get_member(iItem, m_Weapon_flNextSecondaryAttack) <= 0.0) {
		cs_set_user_zoom(pPlayer, cs_get_user_zoom(pPlayer) != CS_SET_FIRST_ZOOM ? CS_SET_FIRST_ZOOM : CS_RESET_ZOOM, 1);

		rh_emit_sound2(pPlayer, 0, CHAN_ITEM, g_szZoomSound, VOL_NORM, ATTN_NORM);

		rg_reset_maxspeed(pPlayer);

		// Задержка по времени для вызова/сброса зума
		const Float: flNextSecondaryAttack = 0.3;

		set_member(iItem, m_Weapon_flNextSecondaryAttack, flNextSecondaryAttack);
	}
}

public RG_CBasePlayerWeapon_Reload_Post(iItem) {
	if(is_nullent(iItem) || !get_member(iItem, m_Weapon_fInReload)) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_connected(pPlayer) || cs_get_user_zoom(pPlayer) != CS_SET_FIRST_ZOOM) {
		return;
	}

	cs_set_user_zoom(pPlayer, CS_RESET_ZOOM, 1);

	rg_reset_maxspeed(pPlayer);
}

public RG_CBasePlayerWeapon_PrimaryAttack_Post(iItem) {
	if(is_nullent(iItem)) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_connected(pPlayer)) {
		return;
	}

	new Float: flNextPrimaryAttack = Float: get_member(iItem, m_Weapon_flNextPrimaryAttack);

	if(flNextPrimaryAttack <= 0.0) {
		return;
	}

	new Float: flCurrentTime = get_gametime();

	if(g_flLastShotTime[pPlayer] == flCurrentTime) {
		return;
	}

	g_flLastShotTime[pPlayer] = flCurrentTime;

	new iClip = get_member(iItem, m_Weapon_iClip);

	if(iClip <= 0 && flNextPrimaryAttack <= 0.2 && !get_member(iItem, m_Weapon_fInReload)) {
		return;
	}

	rh_emit_sound2(pPlayer, 0, CHAN_WEAPON, g_szCustomShotSound, VOL_NORM, ATTN_NORM);

	new bool: bInZoom = bool: (cs_get_user_zoom(pPlayer) == CS_SET_FIRST_ZOOM);

	if(!bInZoom) {
		rg_weapon_send_animation(iItem, 1); // anim shot
	}

	set_entvar(pPlayer, var_effects, get_entvar(pPlayer, var_effects) | EF_MUZZLEFLASH);

	if(iClip == 0 && rg_get_user_bpammo(pPlayer, WEAPON_DEAGLE) > 0) {
		ExecuteHamB(Ham_Weapon_Reload, iItem);
	}

	new Float: flVecOriginStart[3], Float: flVecOriginEnd[3], Float: flVecDirection[3];
	ExecuteHam(Ham_Player_GetGunPosition, pPlayer, flVecOriginStart);
	global_get(glb_v_forward, flVecDirection);
	
	flVecOriginEnd[0] = flVecOriginStart[0] + flVecDirection[0] * 8192.0;
	flVecOriginEnd[1] = flVecOriginStart[1] + flVecDirection[1] * 8192.0;
	flVecOriginEnd[2] = flVecOriginStart[2] + flVecDirection[2] * 8192.0;
	
	engfunc(EngFunc_TraceLine, flVecOriginStart, flVecOriginEnd, IGNORE_MONSTERS, pPlayer, 0);
	
	new Float: flFraction;
	get_tr2(0, TR_flFraction, flFraction);
	
	if(flFraction < 1.0) {
		new pHit = get_tr2(0, TR_pHit);

		if(is_nullent(pHit) || (!is_user_connected(pHit) && get_entvar(pHit, var_solid) != SOLID_BBOX)) {
			new Float: flVecEndPos[3];
			get_tr2(0, TR_vecEndPos, flVecEndPos);

			message_begin_f(MSG_PAS, SVC_TEMPENTITY, flVecEndPos);
			write_byte(TE_GUNSHOTDECAL);
			write_coord_f(flVecEndPos[0]);
			write_coord_f(flVecEndPos[1]);
			write_coord_f(flVecEndPos[2]);
			write_short(pHit);
			write_byte(random_num(41, 45));
			message_end();

			message_begin_f(MSG_PAS, SVC_TEMPENTITY, flVecEndPos);
			write_byte(TE_SPARKS);
			write_coord_f(flVecEndPos[0]);
			write_coord_f(flVecEndPos[1]);
			write_coord_f(flVecEndPos[2]);
			message_end();
		}
	}

	if(bInZoom) {
		// Во сколько раз уменьшим разброс с зумом
		const Float: flWeaponAccuracyWithZoomDiv = 2.0;

		set_member(iItem, m_Weapon_flAccuracy, Float: get_member(iItem, m_Weapon_flAccuracy) / flWeaponAccuracyWithZoomDiv);
	}
}

public fw_SetModel_Pre(eEnt, const szModelPath[]) {
	if(!FClassnameIs(eEnt, "weaponbox") && !FClassnameIs(eEnt, "armoury_entity")) {
		return FMRES_IGNORED;
	}

	if(!equal(szModelPath, g_szDeagleModel_WeaponOld)) {
		return FMRES_IGNORED;
	}

	engfunc(EngFunc_SetModel, eEnt, g_szDeagleModel_Weapon);
	return FMRES_SUPERCEDE;
}

public fw_UpdateClientData_Post(pPlayer, SendWeapons, CD_Handle) {
	if(!is_user_connected(pPlayer)){
		return;
	}

	new iItem = get_member(pPlayer, m_pActiveItem);

	if(is_nullent(iItem) || get_member(iItem, m_iId) != WEAPON_DEAGLE) {
		return;
	}

	set_cd(CD_Handle, CD_flNextAttack, get_gametime () + 0.001);
} 

public fw_PlaybackEvent_Pre(iFlags, pPlayer)
{
	if(!is_user_connected(pPlayer)){
		return FMRES_IGNORED;
	}

	new iItem = get_member(pPlayer, m_pActiveItem);

	if(is_nullent(iItem) || get_member(iItem, m_iId) != WEAPON_DEAGLE) {
		return FMRES_IGNORED;
	}

	return FMRES_SUPERCEDE;
}

Версия	Дата выхода	Размер	Скачиваний	Скачать
0.1	02 авг 2026, 14:15	3.02 MБ	8	Deagle Sniper.zip

От кого	Дата	Сумма	Комментарий
Host-v	02 авг 2026, 14:56	10 ₽	Благодарность за сообщение #189 в разделе «Загрузки»

Кто сейчас на конференции

Зарегистрированные пользователи: Bing [Bot], Google [Bot]

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 10 ₽

Deagle Sniper

Версия: 0.1 02.08.2026 14:15

Кто сейчас на конференции