Код: Выделить всё

// Включить/выключить контроль ослепления
// -
// Default: "1"
// Minimum: "0.000000"
// Maximum: "1.000000"
fc_enable "1"

// Включить/выключить ослепление тиммейтов полностью
// -
// Default: "0"
// Minimum: "0.000000"
// Maximum: "1.000000"
fc_blind_block "0"

// Количество ослеплений тиммейтов до применения наказания
// -
// Default: "3"
fc_blind_count "3"

// Тип наказания
// Отрицательные значения - количество раундов для наказания
// Нулевое значение - наказание до конца карты
// Положительные значения - количество минут для наказания
// -
// Default: "0"
fc_punish_type "0"

// Выводить в чат информацию об ослеплении тиммейтов?
// -
// Default: "1"
// Minimum: "0.000000"
// Maximum: "1.000000"
fc_chat_info "1"

// Флаг полного иммунитета к ослеплению союзников и наказанию
// Оставьте поле пустым, чтобы отключить функцию
// -
// Default: "d"
fc_flag_immunity "d"

Код: Выделить всё

#include <amxmodx>
#include <reapi>
#include <nvault>

new const g_szVerionPlugin[] = "0.1";

enum any: Cvars
{
	CVAR_PLUGIN_ENABLE,
	CVAR_BLIND_BLOCK,
	CVAR_BLIND_COUNT,
	CVAR_PUNISH_TYPE,
	CVAR_CHAT_INFO,
	CVAR_FLAG_IMMUNITY[32]
};

new g_nVault, bool: g_bIsSafe[MAX_PLAYERS+1];
new g_iCvar[Cvars];
new g_iTeammatesBlindCount[MAX_PLAYERS+1];
new bool: g_bIsBlockHavingFlash[MAX_PLAYERS+1], g_iPunishRound[MAX_PLAYERS+1], Float: g_flPunishTime[MAX_PLAYERS+1];

public plugin_init() {
	register_plugin("Flash Control", g_szVerionPlugin, "Kurtis");

	RegisterHookChain(RG_PlayerBlind, "PlayerBlind_Pre");
	RegisterHookChain(RG_CBasePlayer_HasRestrictItem, "CBasePlayer_HasRestrictItem_Pre");
	RegisterHookChain(RG_CBasePlayer_AddPlayerItem, "CBasePlayer_AddPlayerItem_Pre");

	RegisterHookChain(RG_CSGameRules_RestartRound, "CSGameRules_RestartRound_Post", 1);
	set_task(1.0, "_check_tick", .flags = "b");

	RegisterHookChain(RG_CBasePlayer_GetIntoGame, "CBasePlayer_GetIntoGame_Post", 1);
}

public plugin_cfg() {
	_nvault_open();
	_cvars_exec();
}

public plugin_end() {
	if(g_nVault != INVALID_HANDLE) {
		nvault_close(g_nVault);
	}
}

public PlayerBlind_Pre(pVictim, iInflictor, pAttacker, const Float:fadeTime, const Float:fadeHold, const alpha, Float:color[3]) {
	if(!g_iCvar[CVAR_PLUGIN_ENABLE]) {
		return HC_CONTINUE;
	}

	if(!is_user_connected(pVictim) || !is_user_connected(pAttacker)) {
		return HC_CONTINUE;
	}

	if(get_member(pVictim, m_iTeam) != get_member(pAttacker, m_iTeam) || pVictim == pAttacker) {
		return HC_CONTINUE;
	}

	if(g_iCvar[CVAR_BLIND_BLOCK]) {
		return HC_SUPERCEDE;
	}

	if(g_iCvar[CVAR_FLAG_IMMUNITY][0] != EOS) {
		new iFlagsImmunity = read_flags(g_iCvar[CVAR_FLAG_IMMUNITY]);

		if(get_user_flags(pVictim) & iFlagsImmunity) {
			return HC_SUPERCEDE;
		}

		if(get_user_flags(pAttacker) & iFlagsImmunity) {
			return HC_CONTINUE;
		}
	}

	if(g_iCvar[CVAR_BLIND_COUNT] > 0) {
		new Float: flGameTime = get_gametime();
		static Float: flNextTime[MAX_PLAYERS+1];

		if(flNextTime[pAttacker] < flGameTime) {
			g_iTeammatesBlindCount[pAttacker]++;

			if(g_iTeammatesBlindCount[pAttacker] >= g_iCvar[CVAR_BLIND_COUNT] && !g_bIsBlockHavingFlash[pAttacker]) {
				rg_remove_item(pAttacker, "weapon_flashbang");

				if(g_iCvar[CVAR_PUNISH_TYPE] < 0) {
					g_bIsBlockHavingFlash[pAttacker] = true;
					g_iPunishRound[pAttacker] = abs(g_iCvar[CVAR_PUNISH_TYPE]);
				}
				else if(g_iCvar[CVAR_PUNISH_TYPE] > 0) {
					g_bIsBlockHavingFlash[pAttacker] = true;
					g_flPunishTime[pAttacker] = flGameTime + (float(g_iCvar[CVAR_PUNISH_TYPE]) * 60.0);
				}
				else {
					g_bIsBlockHavingFlash[pAttacker] = true;
					g_iPunishRound[pAttacker] = 0;
					g_flPunishTime[pAttacker] = 0.0;
				}

				_fc_block_info(pAttacker, 0.1);
			}
			else {
				if(!g_bIsBlockHavingFlash[pAttacker]) {
					client_print_color(pAttacker, print_team_default, "^4[Flash Control]^1 Предупреждение за ослепление союзников:^3 %i/%i", g_iTeammatesBlindCount[pAttacker], g_iCvar[CVAR_BLIND_COUNT]);
				}
			}

			flNextTime[pAttacker] = flGameTime + 0.1;
		}
	}

	if(g_iCvar[CVAR_CHAT_INFO] > 0) {
		client_print_color(pVictim, print_team_default, "^4[Flash Control]^1 Вас ослепил союзник:^3 %n", pAttacker);
		client_print_color(pAttacker, print_team_default, "^4[Flash Control]^1 Вы ослепили союзника:^3 %n", pVictim);
	}

	return HC_CONTINUE;
}

public CBasePlayer_HasRestrictItem_Pre(pPlayer, ItemID: iItem, ItemRestType: iRestType) {
	if(iRestType != ITEM_TYPE_BUYING || iItem != ITEM_FLASHBANG) {
		return HC_CONTINUE;
	}

	if(!is_user_connected(pPlayer) || !g_bIsBlockHavingFlash[pPlayer]) {
		return HC_CONTINUE;
	}

	_fc_block_info(pPlayer, 1.0);

	SetHookChainReturn(ATYPE_BOOL, true);
	return HC_SUPERCEDE;
}

public CBasePlayer_AddPlayerItem_Pre(pPlayer, iItem) {
	if(is_nullent(iItem) || get_member(iItem, m_iId) != WEAPON_FLASHBANG) {
		return HC_CONTINUE;
	}

	if(!is_user_connected(pPlayer) || !g_bIsBlockHavingFlash[pPlayer]) {
		return HC_CONTINUE;
	}

	rg_remove_entity(iItem);

	_fc_block_info(pPlayer, 3.0);

	SetHookChainReturn(ATYPE_INTEGER, 0);
	return HC_SUPERCEDE;
}

public CSGameRules_RestartRound_Post() {
	if(get_member_game(m_bCompleteReset)) {
		return;
	}

	for(new id = 1; id <= MaxClients; id++) {
		if(g_bIsBlockHavingFlash[id] && g_iPunishRound[id] > 0) {
			g_iPunishRound[id]--;

			if(g_iPunishRound[id] == 0) {
				g_bIsBlockHavingFlash[id] = false;
				g_flPunishTime[id] = 0.0;
			}
		}
	}
}

public _check_tick() {
	new Float: flGameTime = get_gametime();

	for(new id = 1; id <= MaxClients; id++) {
		if(g_bIsBlockHavingFlash[id] && g_flPunishTime[id] > 0) {
			if(g_flPunishTime[id] < flGameTime) {
				g_bIsBlockHavingFlash[id] = false;
				g_flPunishTime[id] = 0.0;
				g_iPunishRound[id] = 0;
			}
		}
	}
}

public _fc_block_info(pPlayer, Float: flTimeCheckFlood) {
	new Float: flGameTime = get_gametime();

	static Float: flNextTime[MAX_PLAYERS+1];

	if(flGameTime < flNextTime[pPlayer]) {
		return;
	}

	flNextTime[pPlayer] = flGameTime + flTimeCheckFlood;

	if(flGameTime < g_flPunishTime[pPlayer]) {
		new iTime = floatround(g_flPunishTime[pPlayer] - flGameTime);
		new iHours = iTime / 3600;
		new iMinutes = (iTime % 3600) / 60;
		new iSeconds = iTime % 60;

		if(iHours > 0) {
			new szHour[16];
			correct_word_hours(iHours, szHour, charsmax(szHour));

			new szMinute[16];
			correct_word_minutes(iMinutes, szMinute, charsmax(szMinute));

			new szSecond[16];
			correct_word_seconds(iSeconds, szSecond, charsmax(szSecond));

			client_print_color(pPlayer, print_team_default, "^4[Flash Control]^1 Установлен запрет владения ослепляющей гранатой:^3 %i %s %i %s %i %s", iHours, szHour, iMinutes, szMinute, iSeconds, szSecond);
		}
		else if(iMinutes > 0) {
			new szMinute[16];
			correct_word_minutes(iMinutes, szMinute, charsmax(szMinute));

			new szSecond[16];
			correct_word_seconds(iSeconds, szSecond, charsmax(szSecond));

			client_print_color(pPlayer, print_team_default, "^4[Flash Control]^1 Установлен запрет владения ослепляющей гранатой:^3 %i %s %i %s", iMinutes, szMinute, iSeconds, szSecond);
		}
		else {
			new szSecond[16];
			correct_word_seconds(iSeconds, szSecond, charsmax(szSecond));

			client_print_color(pPlayer, print_team_default, "^4[Flash Control]^1 Установлен запрет владения ослепляющей гранатой:^3 %i %s", iSeconds, szSecond);
		}
	}
	else if(g_iPunishRound[pPlayer] > 0) {
		new szWord[16];
		correct_word_rounds(g_iPunishRound[pPlayer], szWord, charsmax(szWord));

		client_print_color(pPlayer, print_team_default, "^4[Flash Control]^1 Установлен запрет владения ослепляющей гранатой:^3 %i %s", g_iPunishRound[pPlayer], szWord);
	}
	else {
		client_print_color(pPlayer, print_team_default, "^4[Flash Control]^1 Установлен запрет владения ослепляющей гранатой^3 до конца карты");
	}
}

public client_disconnected(pPlayer) {
	if(!is_user_bot(pPlayer) && !is_user_hltv(pPlayer) && g_bIsSafe[pPlayer]) {
		new szAuthID[MAX_AUTHID_LENGTH];
		get_user_authid(pPlayer, szAuthID, charsmax(szAuthID));

		nvault_set(g_nVault, szAuthID, fmt("%i %i %i %.1f", g_iTeammatesBlindCount[pPlayer], g_bIsBlockHavingFlash[pPlayer], g_iPunishRound[pPlayer], g_flPunishTime[pPlayer]));

		g_bIsSafe[pPlayer] = false;

		g_iTeammatesBlindCount[pPlayer] = 0;

		g_bIsBlockHavingFlash[pPlayer] = false;
		g_iPunishRound[pPlayer] = 0;
		g_flPunishTime[pPlayer] = 0.0;
	}
}

public CBasePlayer_GetIntoGame_Post(pPlayer) {
	if(is_user_connected(pPlayer) && !is_user_bot(pPlayer) && !is_user_hltv(pPlayer)) {
		new szAuthID[MAX_AUTHID_LENGTH];
		get_user_authid(pPlayer, szAuthID, charsmax(szAuthID));

		new szData[64];
		nvault_get(g_nVault, szAuthID, szData, charsmax(szData));

		g_bIsSafe[pPlayer] = true;

		if(szData[0] != EOS) {
			new szCount[8], szBlock[8], szRound[8], szTime[16];
			parse(szData, szCount, charsmax(szCount), szBlock, charsmax(szBlock), szRound, charsmax(szRound), szTime, charsmax(szTime));

			g_iTeammatesBlindCount[pPlayer] = str_to_num(szCount);

			g_bIsBlockHavingFlash[pPlayer] = bool: str_to_num(szBlock);
			g_iPunishRound[pPlayer] = str_to_num(szRound);
			g_flPunishTime[pPlayer] = str_to_float(szTime);
		}
		else {
			g_iTeammatesBlindCount[pPlayer] = 0;

			g_bIsBlockHavingFlash[pPlayer] = false;
			g_iPunishRound[pPlayer] = 0;
			g_flPunishTime[pPlayer] = 0.0;
		}
	}
}

public _nvault_open() {
	g_nVault = nvault_open("fc_store");

	if(g_nVault == INVALID_HANDLE) {
		set_fail_state("Не удалось открыть nVault хранилище, плагин остановлен");
	}
	else {
		nvault_prune(g_nVault, 0, get_systime());
	}
}

public _cvars_exec() {
	bind_pcvar_num(
		create_cvar(
			"fc_enable", "1", FCVAR_SERVER,
			.description = "Включить/выключить контроль ослепления",
			.has_min = true, .min_val = 0.0,
			.has_max = true, .max_val = 1.0
		), g_iCvar[CVAR_PLUGIN_ENABLE]
	);

	bind_pcvar_num(
		create_cvar(
			"fc_blind_block", "0", FCVAR_SERVER,
			.description = "Включить/выключить ослепление тиммейтов полностью",
			.has_min = true, .min_val = 0.0,
			.has_max = true, .max_val = 1.0
		), g_iCvar[CVAR_BLIND_BLOCK]
	);

	bind_pcvar_num(
		create_cvar(
			"fc_blind_count", "3", FCVAR_SERVER,
			.description = "Количество ослеплений тиммейтов до применения наказания"
		), g_iCvar[CVAR_BLIND_COUNT]
	);

	bind_pcvar_num(
		create_cvar(
			"fc_punish_type", "0", FCVAR_SERVER,
			.description = "Тип наказания^n\
			Отрицательные значения - количество раундов для наказания^n\
			Нулевое значение - наказание до конца карты^n\
			Положительные значения - количество минут для наказания"
		), g_iCvar[CVAR_PUNISH_TYPE]
	);

	bind_pcvar_num(
		create_cvar(
			"fc_chat_info", "1", FCVAR_SERVER,
			.description = "Выводить в чат информацию об ослеплении тиммейтов?",
			.has_min = true, .min_val = 0.0,
			.has_max = true, .max_val = 1.0
		), g_iCvar[CVAR_CHAT_INFO]
	);

	bind_pcvar_string(
		create_cvar(
			"fc_flag_immunity", "d", FCVAR_SERVER,
			.description = "Флаг полного иммунитета к ослеплению союзников и наказанию^nОставьте поле пустым, чтобы отключить функцию",
			.has_min = false, .min_val = 0.0,
			.has_max = false, .max_val = 0.0
		), g_iCvar[CVAR_FLAG_IMMUNITY], charsmax(g_iCvar[CVAR_FLAG_IMMUNITY])
	);

	AutoExecConfig(true);
}

// thx the_hanter
enum _:
{
	Plural,
	Singular,
	Nominative
};

stock correct_word_hours(iNum, sWords[], iWordsLen)
{
	switch(get_numerical_noun_form(iNum))
	{
		case Plural: format(sWords, iWordsLen, "часов");
		case Singular: format(sWords, iWordsLen, "часа");
		case Nominative: format(sWords, iWordsLen, "час");
	}
}

stock correct_word_minutes(iNum, sWords[], iWordsLen)
{
	switch(get_numerical_noun_form(iNum))
	{
		case Plural: format(sWords, iWordsLen, "минут");
		case Singular: format(sWords, iWordsLen, "минуты");
		case Nominative: format(sWords, iWordsLen, "минута");
	}
}

stock correct_word_seconds(iNum, sWords[], iWordsLen)
{
	switch(get_numerical_noun_form(iNum))
	{
		case Plural: format(sWords, iWordsLen, "секунд");
		case Singular: format(sWords, iWordsLen, "секунды");
		case Nominative: format(sWords, iWordsLen, "секунда");
	}
}

stock correct_word_rounds(iNum, sWords[], iWordsLen)
{
	switch(get_numerical_noun_form(iNum))
	{
		case Plural: format(sWords, iWordsLen, "раундов");
		case Singular: format(sWords, iWordsLen, "раунда");
		case Nominative: format(sWords, iWordsLen, "раунд");
	}
}

stock get_numerical_noun_form(iNum)
{
	if(iNum > 10 && ((iNum % 100) / 10) == 1)
		return Plural;                   

	switch (iNum % 10)
	{
		case 1: return Nominative;       
		case 2, 3, 4: return Singular;   
	}

	return Plural;                       
}

Код: Выделить всё

#include <amxmodx>
#include <reapi>
#include <nvault>