Show TimeLeft

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 12 ₽

: show_timeleft.sma
2.62 КБ

Добавилrrricardo • 30 авг 2026, 02:22
Авторrrricardo
Версия1.0
Статистика 718 просмотров • 0 комментариев • 1 скачивание

Плагин показывает время до конца карты, вместо времени до конца раунда

Исходный код

► Показать

Код: [Выделить всё] [Развернуть/Свернуть]

public stock const plugin_name[]         = "Show TimeLeft";
public stock const plugin_version[]      = "1.0";
public stock const plugin_author[]       = "rrricardo";
public stock const plugin_url[]          = "nnsstudios.org";
public stock const plugin_description[]  = "Plugin Description";
 
#include <amxmodx>
 
// How often to resync the timer (in seconds)
#define REFRESH_INTERVAL 15.0
 
// Delay before sending a message following ResetHUD
#define SEND_DELAY 0.2
 
#define TASK_REFRESH 8451
#define TASK_PLAYER  9100
 
new g_pTimeLimit;
new g_msgRoundTime;
new g_msgShowTimer;
 
public plugin_init() {
    register_plugin(plugin_name, plugin_version, plugin_author);
 
    g_pTimeLimit = get_cvar_pointer("mp_timelimit");
 
    g_msgRoundTime = get_user_msgid("RoundTime");
    g_msgShowTimer = get_user_msgid("ShowTimer");
 
    register_event("ResetHUD", "Event_ResetHUD", "be");
    register_event("HLTV", "Event_NewRound", "a", "1=0", "2=0");
    register_logevent("LogEvent_RoundStart", 2, "1=Round_Start");
 
    set_task(REFRESH_INTERVAL, "Task_RefreshAll", TASK_REFRESH, .flags = "b");
}
 
public client_putinserver(pPlayer) {
    if (is_user_bot(pPlayer)) {
        return;
    }    
 
    set_task(1.0, "Task_SendToPlayer", TASK_PLAYER + pPlayer);
}
 
public client_disconnected(pPlayer) {
    remove_task(TASK_PLAYER + pPlayer);
}
 
public Event_ResetHUD(pPlayer) {
    if (!is_user_connected(pPlayer) || is_user_bot(pPlayer)) {
        return;
    }
 
    remove_task(TASK_PLAYER + pPlayer);
    set_task(SEND_DELAY, "Task_SendToPlayer", TASK_PLAYER + pPlayer);
}
 
public Event_NewRound() {
    set_task(SEND_DELAY, "Task_RefreshAll", TASK_REFRESH);
}
 
public LogEvent_RoundStart() {
    set_task(SEND_DELAY, "Task_RefreshAll", TASK_REFRESH);
}
 
public Task_SendToPlayer(iTaskId) {
    new pPlayer = iTaskId - TASK_PLAYER;
 
    if (!is_user_connected(pPlayer)) {
        return;
    }
 
    Func_SendTimer(pPlayer);
}
 
public Task_RefreshAll() {
    new iPlayers[MAX_PLAYERS], iNum;
    get_players(iPlayers, iNum, "ch");
 
    for (new i = 0; i < iNum; i++) {
        Func_SendTimer(iPlayers[i]);
    }
}
 
stock Func_SendTimer(pPlayer) {
    if (get_pcvar_float(g_pTimeLimit) <= 0.0) {
        return;
    }
 
    new iTimeLeft = get_timeleft();
 
    if (iTimeLeft <= 0) {
        return;
    }
 
    if (iTimeLeft > 32767) {
        iTimeLeft = 32767;
    }
 
    message_begin(MSG_ONE_UNRELIABLE, g_msgShowTimer, .player = pPlayer);
    message_end();
 
    message_begin(MSG_ONE_UNRELIABLE, g_msgRoundTime, .player = pPlayer);
    write_short(iTimeLeft);
    message_end();
}

Версия	Дата выхода	Размер	Скачиваний	Скачать
1.0	30 авг 2026, 02:22	2.62 КБ	1	show_timeleft.sma

Кто сейчас на конференции

Зарегистрированные пользователи: Amazon [Bot], Baidu [Spider], Google [Bot], Majestic-12 [Bot], Semrush [Bot]

Место свободно

Здесь вы сможете купить рекламу на данном форуме

Стоимость за 1 день 10 ₽

Show TimeLeft

Версия: 1.0 30.08.2026 02:22

Кто сейчас на конференции