Код: Выделить всё

// Радиус действия дыма
const Float: SMOKE_RADIUS = 250.0;
// Периодичность проверки в дыме (тик в секундах)
const Float: THINK_INTERVAL = 1.0;
// Урон за один тик (0.0 — без урона)
const Float: DAMAGE_AMOUNT = 1.0;

// Звуки кашля (выбираются случайно)
new const g_szCoughSounds[][] = {
	"smoke_toxic_gas/cough1.wav",
	"smoke_toxic_gas/cough2.wav",
	"smoke_toxic_gas/cough3.wav",
	"smoke_toxic_gas/cough4.wav",
	"smoke_toxic_gas/cough5.wav"
};

Код: Выделить всё

#include <amxmodx>
#include <hamsandwich>
#include <reapi>

#define TASK_GAS 7841

new const g_szPluginVersion[] = "0.1";

// Радиус действия дыма
const Float: SMOKE_RADIUS = 250.0;
// Периодичность проверки в дыме (тик в секундах)
const Float: THINK_INTERVAL = 1.0;
// Урон за один тик (0.0 — без урона)
const Float: DAMAGE_AMOUNT = 1.0;

// Звуки кашля (выбираются случайно)
new const g_szCoughSounds[][] = {
	"smoke_toxic_gas/cough1.wav",
	"smoke_toxic_gas/cough2.wav",
	"smoke_toxic_gas/cough3.wav",
	"smoke_toxic_gas/cough4.wav",
	"smoke_toxic_gas/cough5.wav",
};

new g_msgScreenFade, g_msgScreenShake;
new bool: g_bIsImminutyToGas[MAX_PLAYERS+1];

public plugin_init() {
	register_plugin("Smoke Toxic Gas", g_szPluginVersion, "Kurtis");

	RegisterHookChain(RG_CGrenade_ExplodeSmokeGrenade, "CGrenade_ExplodeSmokeGrenade_Post", 1);

	g_msgScreenFade = get_user_msgid("ScreenFade");
	g_msgScreenShake = get_user_msgid("ScreenShake");
}

public plugin_precache() {
	for(new i; i < sizeof(g_szCoughSounds); i++) {
		precache_sound(g_szCoughSounds[i]);
	}
}

public client_disconnected(pPlayer) {
	g_bIsImminutyToGas[pPlayer] = false;
}

public CGrenade_ExplodeSmokeGrenade_Post(eEnt) {
	if(is_nullent(eEnt)) {
		return;
	}

	new Float: flVecOrigin[3];
	get_entvar(eEnt, var_origin, flVecOrigin);
	set_entvar(eEnt, var_vuser1, flVecOrigin);

	set_task(THINK_INTERVAL, "_task_toxic_smoke", eEnt + TASK_GAS, .flags = "b");
}

public _task_toxic_smoke(iTask) {
	new eEnt = iTask - TASK_GAS;

	if(is_nullent(eEnt)) {
		remove_task(iTask);
		return;
	}

	new Float: vecOriginEnt[3];
	get_entvar(eEnt, var_vuser1, vecOriginEnt);

	new pPlayers[MAX_PLAYERS], pPlayersCount;
	get_players(pPlayers, pPlayersCount, "a");
	//get_players_ex(pPlayers, pPlayersCount, GetPlayers_ExcludeDead);

	new pAttacker = get_entvar(eEnt, var_owner);
	new bool: bIsAttackerValid;

	if(is_user_connected(pAttacker)) {
		bIsAttackerValid = true;
	}
	else {
		pAttacker = eEnt;
	}

	new Float: flGameTime = get_gametime();
	static Float: flNextTimeUse[MAX_PLAYERS+1];

	for(new i, pVictim; i < pPlayersCount; i++) {
		pVictim = pPlayers[i];

		if(g_bIsImminutyToGas[pVictim]) {
			continue;
		}

		if(flGameTime < flNextTimeUse[pVictim]) {
			continue;
		}

		if(bIsAttackerValid && !rg_is_player_can_takedamage(pVictim, pAttacker)) {
			continue;
		}

		new Float:vecPlayerOrigin[3];
		get_entvar(pVictim, var_origin, vecPlayerOrigin);

		if(get_distance_f(vecOriginEnt, vecPlayerOrigin) > SMOKE_RADIUS) {
			continue;
		}

		flNextTimeUse[pVictim] = flGameTime + THINK_INTERVAL - 0.1;

		_player_gas_effect(pVictim, eEnt, pAttacker);
	}
}

public _player_gas_effect(pVictim, iInflictor, pAttacker) {
	if(DAMAGE_AMOUNT > 0.0) {
		new Float: flUserHealth;
		get_entvar(pVictim, var_health, flUserHealth);

		if(flUserHealth - DAMAGE_AMOUNT < 1.0) {
			ExecuteHamB(Ham_TakeDamage, pVictim, iInflictor, pAttacker, DAMAGE_AMOUNT, DMG_NERVEGAS);
		}
		else {
			set_entvar(pVictim, var_health, flUserHealth - DAMAGE_AMOUNT);
		}
	}

	emit_sound(pVictim, CHAN_VOICE, g_szCoughSounds[random(sizeof(g_szCoughSounds))], VOL_NORM, ATTN_NORM, 0, PITCH_NORM);

	message_begin(MSG_ONE_UNRELIABLE, g_msgScreenFade, _, pVictim);
	write_short(1<<12);        // Длительность эффекта (1<<12 ~= 1 секунда)
	write_short(1<<12);        // Время удержания цвета
	write_short(0x0001);       // Флаг FFADE_IN (плавное появление)
	write_byte(128);            // R (Красный)
	write_byte(128);            // G (Зеленый)
	write_byte(128);            // B (Синий)
	write_byte(180);           // Альфа-канал (0 - прозрачно, 255 - полностью закрашено)
	message_end();

	message_begin(MSG_ONE_UNRELIABLE, g_msgScreenShake, _, pVictim);
	write_short(1<<13);        // Амплитуда тряски
	write_short(1<<13);        // Длительность тряски
	write_short(1<<13);        // Частота тряски
	message_end();
}

public plugin_natives() {
	register_native("is_user_has_immunity_to_gas", "native_is_user_has_immunity_to_gas");
	register_native("set_user_immunity_to_gas", "native_set_user_immunity_to_gas");
	register_native("reset_user_immunity_to_gas", "native_reset_user_immunity_to_gas");
}

public native_is_user_has_immunity_to_gas(plugin_id, num_params) {
	new pPlayer = get_param(1);

	if(!is_user_connected(pPlayer)) {
		return false;
	}

	return g_bIsImminutyToGas[pPlayer];
}

public native_set_user_immunity_to_gas(plugin_id, num_params) {
	new pPlayer = get_param(1);

	if(!is_user_connected(pPlayer)) {
		return false;
	}

	g_bIsImminutyToGas[pPlayer] = true;

	return true;
}

public native_reset_user_immunity_to_gas(plugin_id, num_params) {
	new pPlayer = get_param(1);

	if(!is_user_connected(pPlayer)) {
		return false;
	}

	g_bIsImminutyToGas[pPlayer] = false;

	return true;
}

Код: Выделить всё

// Возвращает true, если игрок имеет иммунитет, false - иначе
// pPlayer - индекс игрока
native is_user_has_immunity_to_gas(pPlayer);

// Устанавливает иммунитет к газу для игрока
// pPlayer - индекс игрока
// Возвращает true в случае успеха, false - иначе
native set_user_immunity_to_gas(pPlayer);

// Сбрасывает иммунитет к газу для игрока
// pPlayer - индекс игрока
// Возвращает true в случае успеха, false - иначе
native reset_user_immunity_to_gas(pPlayer);

// Иммунитет к газу автоматически сбрасывается при выходе с сервера игрока, поэтому дублировать это нативом не нужно