Медик

: Medic.zip
2.57 MБ

ДобавилKurtis • 05 янв 2025, 14:09
АвторKurtis
Версия1.0
Статистика 849 просмотров • 0 комментариев • 8 скачиваний

Небольшой плагин: Медик.
Добавляет привилегию медика на ваш сервер.

Возможности медика:

Имеет своё количество HP

Имеет собственную модель

Имеет возможность единичного возрождения после смерти

Имеет возможность лечить союзников и себя (для этого нужно атаковать союзника и чтобы при этом у медика или у союзника было меньше определенного количества HP). Сопровождается эффектом искр и звуком.

Установка: Закинуть содержимое архива себе на сервер в папку cstrike/.
Скомпилировать исходник, поместить плагин в папку с плагинами.
Прописать название плагина в файле со списком плагинов.
Настроить конфиг на своё усмотрение.

Настройка

Код: [Выделить всё] [Развернуть/Свернуть]

// Настройки плагина
 
// Флаг доступа для привилегии медика
medic_flags         = "t"
 
// Устанавливаемое здоровье медику при возрождении
medic_health            = 105
 
// Возрождать ли медика после смерти? (1 - да, 0 - нет; работает 1 раз за раунд)
medic_respawn_enable        = 1
 
// Сколько ХП устанавливать медику после возрождения? (1 - да, 0 - нет; при `medic_respawn_enable` = 1)
medic_respawn_health        = 50
 
// Включить лечение союзников и себя при попадании медиком по союзнику? (1 - да, 0 - нет)
medic_heal_teammate_enable  = 1
 
// Перезарядка после активации лечения (в секундах; при `medic_heal_teammate_enable` = 1)
medic_heal_reload       = 60
 
// Меньше скольки ХП должно быть у союзника, чтобы медик, нанеся урон по нему, мог запустить лечение? (1 - да, 0 - нет)
medic_heal_teammate_min_hp  = 100
 
// Создавать эффект лечения - звук и искры? (1 - да, 0 - нет; при `medic_heal_teammate_enable` = 1)
medic_heal_teammate_effect  = 1
 
// До скольки ХП может вылечить медик? (для медиков будет сравниваться с `medic_health`; при `medic_heal_teammate_enable` = 1)
medic_heal_teammate_max_hp  = 100
 
// Модель игрока медика для террористов (только название модели в папке player; пустая строка - "" - выключает установку модели)
medic_model_path_te     = "medic_te"
 
// Установка типа _body для модели террористов (при установке модели `medic_model_path_te`)
medic_model_body_te     = 0
 
// Установка типа _skin для модели террористов (при установке модели `medic_model_path_te`)
medic_model_skin_te     = 0
 
// Модель игрока медика для контр-террористов (только название модели в папке player; пустая строка - "" - выключает установку модели)
medic_model_path_ct     = "medic_ct"
 
// Установка типа _body для модели контр-террористов (при установке модели `medic_model_path_ct`)
medic_model_body_ct     = 0
 
// Установка типа _skin для модели контр-террористов (при установке модели `medic_model_path_ct`)
medic_model_skin_ct     = 0

Исходный код

Код: [Выделить всё] [Развернуть/Свернуть]

#include <amxmodx>
#include <reapi>
 
enum _: eSettingMedic {
    MedicFlags,
    MedicHealth,
    MedicRespawnEnable,
    MedicRespawnHealth,
    MedicHealTeammateReload,
    MedicHealTeammateMinHp,
    MedicHealTeammateEffect,
    MedicHealTeammateMaxHealth,
    MedicModelPlayerPathTe[MAX_RESOURCE_PATH_LENGTH],
    MedicModelPlayerBodyTe,
    MedicModelPlayerSkinTe,
    MedicModelPlayerPathCt[MAX_RESOURCE_PATH_LENGTH],
    MedicModelPlayerBodyCt,
    MedicModelPlayerSkinCt
};
 
new const g_szSparkSounds[][] = {
    "buttons/spark1.wav",
    "buttons/spark2.wav",
    "buttons/spark3.wav",
    "buttons/spark4.wav",
    "buttons/spark5.wav",
    "buttons/spark6.wav",
};
 
new const g_szSparkSprite[] = "sprites/fexplo.spr";
 
const TASK_THINK = 1337;
 
new g_iIndexSparkSprite;
new g_eCvarSetting[eSettingMedic];
new bool: g_bIsUserMedic[MAX_PLAYERS+1];
new bool: g_bIsMedicRespawned[MAX_PLAYERS+1];
new Float: g_flMedicUseHealReload[MAX_PLAYERS+1];
 
public plugin_precache() {
    register_plugin("Privilege: Medic", "1.0", "Kurtis");
 
    new const szConfigPath[] = "addons/amxmodx/configs/medic_privilege.cfg";
 
    if(!file_exists(szConfigPath)) {
        set_fail_state("Конфиг ^"%s^" не загружен. Плагин остановлен", szConfigPath);
        return;
    }
 
    new INIParser: iParser = INI_CreateParser();
 
    INI_SetReaders(iParser, "INI_ReadKeyValue");
    INI_ParseFile(iParser, szConfigPath);
 
    INI_DestroyParser(iParser);
}
 
public plugin_init() {
    RegisterHookChain(RG_CSGameRules_RestartRound, "CSGameRules_RestartRound_Post", 1);
    RegisterHookChain(RG_CSGameRules_PlayerSpawn, "CSGameRules_PlayerSpawn_Post", 1);
    RegisterHookChain(RG_CSGameRules_PlayerKilled, "CSGameRules_PlayerKilled_Post", 1);
}
 
public client_disconnected(pPlayer) {
    remove_task(pPlayer);
    remove_task(pPlayer + TASK_THINK);
 
    g_bIsUserMedic[pPlayer] = false;
}
 
public CSGameRules_RestartRound_Post() {
    arrayset(g_bIsMedicRespawned, 0, MAX_PLAYERS+1);
}
 
public CSGameRules_PlayerSpawn_Post(pPlayer) {
    remove_task(pPlayer);
    remove_task(pPlayer + TASK_THINK);
 
    g_flMedicUseHealReload[pPlayer] = 0.0;
 
    if(!is_user_alive(pPlayer)) {
        return;
    }
 
    set_task(1.0, "task_set_user_medic_prop", pPlayer);
}
 
public CSGameRules_PlayerKilled_Post(pVictim, pKiller, iInflictor) {
    remove_task(pVictim);
    remove_task(pVictim + TASK_THINK);
 
    if(!g_bIsMedicRespawned[pVictim] && g_bIsUserMedic[pVictim])
    {
        client_print_color(pVictim, print_team_default, "^1[^4Медик^1] Возрождение активировано. Вы возродитесь через^4 2.5 сек");
 
        remove_task(pVictim);
        set_task(2.5, "task_medic_respawn", pVictim);
    }
 
    g_bIsUserMedic[pVictim] = false;
}
 
public CBasePlayer_TakeDamage_Post(pVictim, iInflictor, pAttacker, Float: flDamage, bitsDamageType) {
    if(!is_user_connected(pAttacker) || pVictim == pAttacker || !g_bIsUserMedic[pAttacker] || get_member(pVictim, m_iTeam) != get_member(pAttacker, m_iTeam) || g_flMedicUseHealReload[pAttacker] > get_gametime()) {
        return;
    }
 
    if(Float: get_entvar(pVictim, var_health) < Float: float(g_eCvarSetting[MedicHealTeammateMinHp]) && !task_exists(pVictim + TASK_THINK) ||
    Float: get_entvar(pAttacker, var_health) < float(g_eCvarSetting[MedicHealTeammateMinHp]) && !task_exists(pAttacker + TASK_THINK)) {
        set_task(0.1, "task_user_regen", pVictim + TASK_THINK, .flags = "b");
        set_task(0.1, "task_user_regen", pAttacker + TASK_THINK, .flags = "b");
 
        g_flMedicUseHealReload[pAttacker] = get_gametime() + float(g_eCvarSetting[MedicHealTeammateReload]);
 
        client_print_color(pAttacker, print_team_default, "^1[^4Медик^1] Лечение активировано. Повторная активация через^4 %i сек", g_eCvarSetting[MedicHealTeammateReload]);
    }
}
 
public task_user_regen(pPlayer)
{
    pPlayer -= TASK_THINK;
 
    static Float: flGameTime;
    flGameTime = get_gametime();
 
    static Float: flNextUse[MAX_PLAYERS+1];
 
    if(flNextUse[pPlayer] < flGameTime) {
        flNextUse[pPlayer] = flGameTime + random_float(0.3, 0.7);
 
        static Float: flHealth;
        flHealth = Float: get_entvar(pPlayer, var_health);
 
        if(g_bIsUserMedic[pPlayer]) {
            if(flHealth < g_eCvarSetting[MedicHealth]) {
                if(g_eCvarSetting[MedicHealTeammateEffect]) {
                    emit_sound(pPlayer, CHAN_AUTO, g_szSparkSounds[random(sizeof(g_szSparkSounds))], VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
                }
 
                set_entvar(pPlayer, var_health, floatclamp(flHealth + random_float(2.0, 4.0), 1.0, float(g_eCvarSetting[MedicHealth])));
            }
            else {
                remove_task(pPlayer + TASK_THINK);
                return;
            }
        }
        else {
            if(flHealth < g_eCvarSetting[MedicHealTeammateMaxHealth]) {
                if(g_eCvarSetting[MedicHealTeammateEffect]) {
                    emit_sound(pPlayer, CHAN_AUTO, g_szSparkSounds[random(sizeof(g_szSparkSounds))], VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
                }
 
                set_entvar(pPlayer, var_health, floatclamp(flHealth + random_float(1.0, 3.0), 1.0, float(g_eCvarSetting[MedicHealTeammateMaxHealth])));
            }
            else {
                remove_task(pPlayer + TASK_THINK);
                return;
            }
        }
    }
 
    if(g_eCvarSetting[MedicHealTeammateEffect]) {
 
        static Float: vecOriginStart[3];
        get_entvar(pPlayer, var_origin, vecOriginStart);
 
        static Float: vecOriginEnd[3];
        vecOriginEnd = vecOriginStart;
 
        vecOriginStart[2] -= 40;
        vecOriginEnd[2] += 30;
 
        message_begin_f(MSG_BROADCAST, SVC_TEMPENTITY);
        write_byte(TE_BEAMPOINTS);
        write_coord_f(vecOriginStart[0]);   // start position
        write_coord_f(vecOriginStart[1]);
        write_coord_f(vecOriginStart[2]);
        write_coord_f(vecOriginEnd[0]); // end position
        write_coord_f(vecOriginEnd[1]);
        write_coord_f(vecOriginEnd[2]);
        write_short(g_iIndexSparkSprite);   // sprite index
        write_byte(1);  // starting frame
        write_byte(5);  // frame rate in 0.1's
        write_byte(1);  // life in 0.1's
        write_byte(20); // line width in 0.1's
        write_byte(255);    // noise amplitude in 0.01's
        write_byte(240);    // Red
        write_byte(225);    // Green
        write_byte(232);    // Blue
        write_byte(255);    // brightness
        write_byte(100);    // scroll speed in 0.1's
        message_end();
    }
}
 
public task_medic_respawn(pPlayer) {
    if(!is_user_alive(pPlayer)) {
        g_bIsMedicRespawned[pPlayer] = true;
        rg_round_respawn(pPlayer);
 
        client_print_color(pPlayer, print_team_default, "^1[^4Медик^1] Вы возрождены. В этом раунде больше нет второго шанса");
    }
}
 
public task_set_user_medic_prop(pPlayer) {
    if(get_user_flags(pPlayer) & g_eCvarSetting[MedicFlags]) {
        g_bIsUserMedic[pPlayer] = true;
 
        switch(get_member(pPlayer, m_iTeam))
        {
            case TEAM_TERRORIST: {
                if(g_eCvarSetting[MedicModelPlayerPathTe][0] != EOS)
                    rg_set_user_model(pPlayer, g_eCvarSetting[MedicModelPlayerPathTe]);
            }
 
            case TEAM_CT: {
                if(g_eCvarSetting[MedicModelPlayerPathCt][0] != EOS)
                    rg_set_user_model(pPlayer, g_eCvarSetting[MedicModelPlayerPathCt]);
            }
        }
 
        if(g_bIsMedicRespawned[pPlayer]) {
            set_entvar(pPlayer, var_health, floatclamp(float(g_eCvarSetting[MedicRespawnHealth]), 1.0, float(g_eCvarSetting[MedicRespawnHealth])));
        }
        else {
            set_entvar(pPlayer, var_health, floatclamp(float(g_eCvarSetting[MedicHealth]), 1.0, float(g_eCvarSetting[MedicHealth])));
        }
    }
    else {
        g_bIsUserMedic[pPlayer] = false;
    }
}
 
public bool: INI_ReadKeyValue(INIParser: iParser, const szKey[], const szValue[]) {
    if(szKey[0] == EOS) {
        return true;
    }
 
    new szString[128];
    format(szString, charsmax(szString), "%s", szValue);
    trim(szString);
 
    if(equal(szKey, "medic_flags")) {
        g_eCvarSetting[MedicFlags] = read_flags(szString);
    }
    else if(equal(szKey, "medic_health")) {
        g_eCvarSetting[MedicHealth] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_respawn_enable")) {
        g_eCvarSetting[MedicRespawnEnable] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_respawn_health")) {
        g_eCvarSetting[MedicRespawnHealth] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_heal_teammate_enable") && str_to_num(szString)) {
        RegisterHookChain(RG_CBasePlayer_TakeDamage, "CBasePlayer_TakeDamage_Post", 1);
    }
    else if(equal(szKey, "medic_heal_reload")) {
        g_eCvarSetting[MedicHealTeammateReload] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_heal_teammate_min_hp")) {
        g_eCvarSetting[MedicHealTeammateMinHp] = str_to_num(szString);
    }   
    else if(equal(szKey, "medic_heal_teammate_effect")) {
        g_eCvarSetting[MedicHealTeammateEffect] = str_to_num(szString);
 
        for(new i; i < sizeof(g_szSparkSounds); i++)
            precache_sound(g_szSparkSounds[i]);
 
        g_iIndexSparkSprite = precache_model(g_szSparkSprite);
    }
    else if(equal(szKey, "medic_heal_teammate_max_hp")) {
        g_eCvarSetting[MedicHealTeammateMaxHealth] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_model_path_te")) {
        format(g_eCvarSetting[MedicModelPlayerPathTe], charsmax(g_eCvarSetting[MedicModelPlayerPathTe]), "%s", szString);
 
        if(szString[0] != EOS)
            precache_model(fmt("models/player/%s/%s.mdl", g_eCvarSetting[MedicModelPlayerPathTe], g_eCvarSetting[MedicModelPlayerPathTe]));
    }
    else if(equal(szKey, "medic_model_body_te")) {
        g_eCvarSetting[MedicModelPlayerBodyTe] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_model_skin_te")) {
        g_eCvarSetting[MedicModelPlayerSkinTe] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_model_path_ct")) {
        format(g_eCvarSetting[MedicModelPlayerPathCt], charsmax(g_eCvarSetting[MedicModelPlayerPathCt]), "%s", szString); 
 
        if(szString[0] != EOS)
            precache_model(fmt("models/player/%s/%s.mdl", g_eCvarSetting[MedicModelPlayerPathCt], g_eCvarSetting[MedicModelPlayerPathCt]));
    }
    else if(equal(szKey, "medic_model_body_ct")) {
        g_eCvarSetting[MedicModelPlayerBodyCt] = str_to_num(szString);
    }
    else if(equal(szKey, "medic_model_skin_ct")) {
        g_eCvarSetting[MedicModelPlayerSkinCt] = str_to_num(szString);
    }
 
    return true;
}

Версия	Дата выхода	Размер	Скачиваний	Скачать
1.0	05 янв 2025, 14:05	2.57 MБ	8	Medic.zip

От кого	Дата	Сумма	Комментарий
Host-v	05 янв 2025, 14:44	10 ₽	Благодарность за сообщение #134 в разделе «Загрузки»

Кто сейчас на конференции

Зарегистрированные пользователи: Ahrefs [Bot], Semrush [Bot]

Медик

Версия: 1.0 05.01.2025 14:05

Кто сейчас на конференции