Copter | Коптер - Ресурсы -

Место свободно
Здесь вы сможете купить рекламу на данном форуме
Стоимость за 1 день 15 ₽
Copter | Коптер

Скидка -25% до 1 янв 23:59
: Copter.zip
221.35 КБ; Купить за ~~800~~ 600 ₽; Другие ресурсы пользователя Kurtis

Случайный волшебник

Медик
Небольшой плагин: Медик.
ДобавилKurtis • Вчера, 21:10
АвторKurtis
Версия0.1
Статистика 26 просмотров • 0 комментариев • 0 скачиваний
Коптер с несколькими режимами.

Режимы:
1. Бездействие. Коптер просто висит в воздухе.
2. Атака противников. Коптер атакует противников в зоне видимости.
3. Ручное управление. Коптером можно управлять вручную, в том числе и стрелять на ЛКМ.
4. Камикадзе. Коптер лежит к ближайшей цели и взрывается, нанося урон всем врагам в радиусе взрыва.
Исходный код
Код: Выделить всё
#include <amxmodx>
#include <amxmisc>
#include <fakemeta_util>
#include <hamsandwich>
#include <reapi>

#define COPTER_MODEL "models/copter/copter.mdl"
#define COPTER_SOUND "copter/copter.wav"
#define COPTER_SOUND_LASER "copter/primary_laser.wav"
#define COPTER_IMPULSE 555

// Раскоментируйте, чтобы включить фуллпак (добавляет немного реалистичности игроку при управлении коптером)
//#define FULLPACK_ON

new g_eEntCopter[MAX_PLAYERS+1];
new g_iModeCopter[MAX_PLAYERS+1];
new g_iMenuCopter[MAX_PLAYERS+1];
new g_iSpriteExp, g_iSpriteBeam;
new g_iCopterCost, Float: g_flCopterHealth, Float: g_flCopterDamage;

enum _: eModeCopter {
	Mode_Draw,
	Mode_Attack,
	Mode_Control,
	Mode_Kamikadze
};

public plugin_init() {
	register_plugin("Copter", "0.1", "Kurtis");

	register_clcmd("copter", "copter_menu");
	register_clcmd("say /copter", "copter_menu");

	RegisterHookChain(RG_CSGameRules_PlayerSpawn, "CSGameRules_PlayerSpawn_Post", 1);
	RegisterHookChain(RG_CSGameRules_PlayerKilled, "CSGameRules_PlayerKilled_Post", 1);
	RegisterHookChain(RG_CBasePlayer_PreThink, "CBasePlayer_PreThink", 0);
	RegisterHookChain(RG_CBasePlayer_ResetMaxSpeed, "RG_CBasePlayer_ResetMaxSpeed_Pre", 0);
	RegisterHookChain(RG_CBasePlayer_Jump, "RG_CBasePlayer_Jump_Pre", 0);
	RegisterHookChain(RG_CBasePlayer_Duck, "RG_CBasePlayer_Duck_Pre", 0);
	RegisterHookChain(RG_CBasePlayerWeapon_DefaultDeploy, "CBasePlayerWeapon_DefaultDeploy_Post", 1);

	RegisterHam(Ham_TakeDamage, "info_target", "Ham_TakeDamage_Copter_Pre", 0);
	RegisterHam(Ham_Killed, "info_target", "Ham_Killed_Copter_Pre", 0);

#if defined FULLPACK_ON
	register_forward(FM_AddToFullPack, "Fwd_AddToFullPack_Post", 1);
	#endif
}

public plugin_precache() {
	load_config();

	precache_model(COPTER_MODEL);

	g_iSpriteExp = precache_model("sprites/dexplo.spr");
	g_iSpriteBeam = precache_model("sprites/zbeam1.spr");

	precache_sound(COPTER_SOUND);
	precache_sound(COPTER_SOUND_LASER);
}

public client_disconnected(pPlayer) {
	_remove_ent(g_eEntCopter[pPlayer]);

	g_eEntCopter[pPlayer] = NULLENT;
	g_iModeCopter[pPlayer] = Mode_Draw;
}

public copter_menu(pPlayer) {
	if(!is_user_alive(pPlayer)) {
		return;
	}

	new iMenu = menu_create("\yУправление коптером", "copter_menu_handler");

	if(is_nullent(g_eEntCopter[pPlayer])) {
		menu_additem(iMenu, fmt("\%cКупить коптер \d[\r%i$]^n", get_member(pPlayer, m_iAccount) >= g_iCopterCost ? 'w' : 'd', g_iCopterCost));

		menu_additem(iMenu, "\dРежим коптера: \rбездействие");
		menu_additem(iMenu, "\dРежим коптера: \rатака противников");
		menu_additem(iMenu, "\dРежим коптера: \rручное управление");
		menu_additem(iMenu, "\dРежим коптера: \rкамикадзе");
	}
	else {
		menu_additem(iMenu, "\wВзорвать коптер^n");

		menu_additem(iMenu, fmt("\%cРежим коптера: \rбездействие", g_iModeCopter[pPlayer] == Mode_Draw ? 'w' : 'd'));
		menu_additem(iMenu, fmt("\%cРежим коптера: \rатака противников", g_iModeCopter[pPlayer] == Mode_Attack ? 'w' : 'd'));
		menu_additem(iMenu, fmt("\%cРежим коптера: \rручное управление", g_iModeCopter[pPlayer] == Mode_Control ? 'w' : 'd'));
		menu_additem(iMenu, fmt("\%cРежим коптера: \rкамикадзе", g_iModeCopter[pPlayer] == Mode_Kamikadze ? 'w' : 'd'));
	}

	menu_setprop(iMenu, MPROP_EXITNAME, "\wВыход");
	menu_display(pPlayer, iMenu);

	g_iMenuCopter[pPlayer] = iMenu;
}

public copter_menu_handler(pPlayer, iMenu, iItem) {
	menu_destroy(iMenu);

	if(!is_user_alive(pPlayer)) {
		return;
	}

	switch(iItem)
	{
		case MENU_EXIT:{
			return;
		}

		case 0: {
			if(is_nullent(g_eEntCopter[pPlayer])) {
				if(get_member(pPlayer, m_iAccount) >= g_iCopterCost) {
					new Float: flVecOrigin[3];
					get_player_origin_front(pPlayer, flVecOrigin, 100.0);
					flVecOrigin[2] += 5.0;

					if(is_hull_vacant(flVecOrigin, HULL_HUMAN, 0)) {
						g_eEntCopter[pPlayer] = rg_create_entity("info_target");

						if(is_nullent(g_eEntCopter[pPlayer])) {
							client_print_color(pPlayer, print_team_default, "Что-то пошло не так, попробуйте позже");

							return;
						}

						rg_add_account(pPlayer, -g_iCopterCost);

						engfunc(EngFunc_SetModel, g_eEntCopter[pPlayer], COPTER_MODEL);
						engfunc(EngFunc_SetOrigin, g_eEntCopter[pPlayer], flVecOrigin);
						engfunc(EngFunc_SetSize, g_eEntCopter[pPlayer], Float: {-15.0, -14.0, -4.0}, Float: {10.0, 13.0, 1.0});

						set_entvar(g_eEntCopter[pPlayer], var_classname, "copter");
						set_entvar(g_eEntCopter[pPlayer], var_solid, SOLID_BBOX);
						set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_FLY);
						set_entvar(g_eEntCopter[pPlayer], var_euser1, pPlayer);
						set_entvar(g_eEntCopter[pPlayer], var_takedamage, DAMAGE_YES);
						set_entvar(g_eEntCopter[pPlayer], var_health, g_flCopterHealth);
						set_entvar(g_eEntCopter[pPlayer], var_gravity, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_sequence, 1);
						set_entvar(g_eEntCopter[pPlayer], var_animtime, 0.5);
						set_entvar(g_eEntCopter[pPlayer], var_framerate, 30.0);
						set_entvar(g_eEntCopter[pPlayer], var_fuser1, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_fuser2, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_fuser3, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_fuser4, 0.0);
						set_entvar(g_eEntCopter[pPlayer], var_impulse, COPTER_IMPULSE);

						g_iModeCopter[pPlayer] = Mode_Draw;
					}
					else {
						client_print_color(pPlayer, print_team_default, "Перед вами недостаточно места для создания коптера");
					}
				}
				else {
					client_print_color(pPlayer, print_team_default, "У вас не хватает ^4денег ^1для покупки ^3коптера");
					return;
				}
			}
			else {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Draw;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_TOSS);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}

				if(!is_nullent(g_eEntCopter[pPlayer])) {
					copter_explode(g_eEntCopter[pPlayer]);
				}

				_remove_ent(g_eEntCopter[pPlayer]);
				g_eEntCopter[pPlayer] = NULLENT;
				client_print_color(pPlayer, print_team_default, "Вы взорвали свой ^3коптер");

				return;
			}
		}

		case 1: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Draw;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_FLY);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
				else {
					g_iModeCopter[pPlayer] = Mode_Draw;
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);
				}
			}
		}

		case 2: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Attack;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_FLY);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
				else {
					g_iModeCopter[pPlayer] = Mode_Attack;
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);
				}
			}
		}

		case 3: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] != Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Control;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_TOSS);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					set_entvar(pPlayer, var_maxspeed, -1.0);
					engset_view(pPlayer, g_eEntCopter[pPlayer]);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
			}
		}

		case 4: {
			if(!is_nullent(g_eEntCopter[pPlayer])) {
				if(g_iModeCopter[pPlayer] == Mode_Control) {
					g_iModeCopter[pPlayer] = Mode_Kamikadze;
					set_entvar(g_eEntCopter[pPlayer], var_movetype, MOVETYPE_TOSS);
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);

					rg_reset_maxspeed(pPlayer);
					engset_view(pPlayer, pPlayer);

					new iActiveItem = get_member(pPlayer, m_pActiveItem);

					if(!is_nullent(iActiveItem)) {
						ExecuteHamB(Ham_Item_Deploy, iActiveItem);
					}
				}
				else {
					g_iModeCopter[pPlayer] = Mode_Kamikadze;
					set_entvar(g_eEntCopter[pPlayer], var_velocity, NULL_VECTOR);
				}
			}
		}
	}

	RequestFrame("copter_menu", pPlayer);
}

public CSGameRules_PlayerSpawn_Post(pPlayer) {
	if(!is_user_alive(pPlayer)) {
		return;
	}

	_remove_ent(g_eEntCopter[pPlayer]);

	if(g_iModeCopter[pPlayer] == Mode_Control) {
		engset_view(pPlayer, pPlayer);
	}

	player_close_menu_copter(pPlayer);

	g_eEntCopter[pPlayer] = NULLENT;
	g_iModeCopter[pPlayer] = Mode_Draw;
}

public CSGameRules_PlayerKilled_Post(pVictim, pKiller, iInflictor) {
	if(!is_user_connected(pVictim)) {
		return;
	}

	_remove_ent(g_eEntCopter[pVictim]);

	if(g_iModeCopter[pVictim] == Mode_Draw) {
		engset_view(pVictim, pVictim);
	}

	player_close_menu_copter(pVictim);

	g_eEntCopter[pVictim] = NULLENT;
	g_iModeCopter[pVictim] = Mode_Draw;
}

public CBasePlayer_PreThink(pPlayer) {
	if(!is_user_alive(pPlayer) || is_nullent(g_eEntCopter[pPlayer])) {
		return;
	}

	static Float: flGameTime; flGameTime = get_gametime();

	if(get_entvar(g_eEntCopter[pPlayer], var_fuser1) < flGameTime) {
		set_entvar(g_eEntCopter[pPlayer], var_fuser1, flGameTime + 2.0);
		rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
	}

	switch(g_iModeCopter[pPlayer]) {
		case Mode_Attack: {
			if(get_entvar(g_eEntCopter[pPlayer], var_fuser3) < flGameTime) {
				set_entvar(g_eEntCopter[pPlayer], var_fuser3, flGameTime + 0.3);

				new pVictim = NULLENT;
				pVictim = find_range_enemy(pPlayer, g_eEntCopter[pPlayer]);

				if(pVictim == NULLENT) {
					return;
				}

				new Float: flVecOriginVictim[3];
				get_entvar(pVictim, var_origin, flVecOriginVictim);
				flVecOriginVictim[2] += random_float(-10.0, 10.0);

				CREATE_BEAMENTPOINT(g_eEntCopter[pPlayer], flVecOriginVictim, g_iSpriteBeam, 0, 0, 1, 1, 1, 255, 255, 72, 255, 0);
				ExecuteHamB(Ham_TakeDamage, pVictim, g_eEntCopter[pPlayer], pPlayer, g_flCopterDamage, DMG_ENERGYBEAM);
				rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_LASER, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
			}
		}

		case Mode_Control: {
			new iButton = get_entvar(pPlayer, var_button);

			new Float: flVecVelocity[3], Float: flVecAngles[3];
			get_entvar(pPlayer, var_angles, flVecAngles);

			if(iButton & IN_FORWARD) {
				velocity_by_aim(pPlayer, 240, flVecVelocity);
				flVecVelocity[2] *= -1.0;
			}
			else if(iButton & IN_BACK) {
				velocity_by_aim(pPlayer, -240, flVecVelocity);
				flVecVelocity[2] *= -1.0;
			}

			set_entvar(g_eEntCopter[pPlayer], var_angles, flVecAngles);
			set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);

			set_entvar(pPlayer, var_sequence, 13);
			set_entvar(pPlayer, var_gaitsequence, 0);
			set_entvar(pPlayer, var_velocity, NULL_VECTOR);

			if(iButton & IN_ATTACK) {
				if(get_entvar(g_eEntCopter[pPlayer], var_fuser3) < flGameTime) {
					set_entvar(g_eEntCopter[pPlayer], var_fuser3, flGameTime + 0.3);

					new Float: flVecOriginEnd[3];
					new pVictim = get_origin_aiming_ent(g_eEntCopter[pPlayer], flVecOriginEnd);

					if(is_user_alive(pVictim) && get_member(pPlayer, m_iTeam) != get_member(pVictim, m_iTeam)) {
						new Float: flVecOriginVictim[3];
						get_entvar(pVictim, var_origin, flVecOriginVictim);
						flVecOriginVictim[2] += random_float(-10.0, 10.0);

						CREATE_BEAMENTPOINT(g_eEntCopter[pPlayer], flVecOriginVictim, g_iSpriteBeam, 0, 0, 1, 1, 1, 255, 255, 72, 255, 0);
						ExecuteHamB(Ham_TakeDamage, pVictim, g_eEntCopter[pPlayer], pPlayer, g_flCopterDamage, DMG_ENERGYBEAM);
						rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_LASER, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
					}
					else {
						new Float: flVecOriginStart[3];
						get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginStart);
	
						CREATE_BEAMPOINTS(flVecOriginStart, flVecOriginEnd, g_iSpriteBeam, 0, 0, 1, 1, 1, 255, 255, 72, 255, 0);
						rh_emit_sound2(g_eEntCopter[pPlayer], 0, CHAN_STATIC, COPTER_SOUND_LASER, VOL_NORM, ATTN_NORM, 0, PITCH_NORM, SND_EMIT2_NOPAS, Float: {0.0, 0.0, 0.0});
					}
				}
			}
		}

		case Mode_Kamikadze:
		{
			new pVictim = NULLENT;

			if(get_entvar(g_eEntCopter[pPlayer], var_fuser2) < flGameTime) {
				set_entvar(g_eEntCopter[pPlayer], var_fuser2, flGameTime + 0.1);

				pVictim = find_range_enemy(pPlayer, g_eEntCopter[pPlayer]);

				if(pVictim == NULLENT) {
					return;
				}

				new Float: flVecOriginStart[3], Float: flVecOriginEnd[3], Float: flVecVelocity[3], Float: flDist;
				get_entvar(g_eEntCopter[pPlayer], var_origin, flVecOriginStart);
				get_entvar(pVictim, var_origin, flVecOriginEnd);

				flDist = get_distance_f(flVecOriginStart, flVecOriginEnd);

				if(flDist < 50.0) {
					copter_explode(g_eEntCopter[pPlayer]);
					_remove_ent(g_eEntCopter[pPlayer]);
					g_eEntCopter[pPlayer] = NULLENT;

					player_close_menu_copter(pPlayer);
					return;
				}

				xs_vec_sub(flVecOriginEnd, flVecOriginStart, flVecVelocity);

				if(flDist < 200.0) {
					xs_vec_mul_scalar(flVecVelocity, 2.0, flVecVelocity);
				}

				set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);
			}
		}
	}
}

public copter_explode(eEnt) {
	new Float: flVecOriginStart[3], Float: flVecOriginEnd[3];
	get_entvar(eEnt, var_origin, flVecOriginStart);

	message_begin_f(MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_EXPLOSION);
	write_coord_f(flVecOriginStart[0]);
	write_coord_f(flVecOriginStart[1]);
	write_coord_f(flVecOriginStart[2]);
	write_short(g_iSpriteExp);
	write_byte(30); // scale
	write_byte(10); // framerate
	write_byte(TE_EXPLFLAG_NONE);
	message_end(); 

	new pOwner = get_entvar(eEnt, var_euser1);

	if(!is_user_alive(pOwner)) {
		return;
	}

	new iPlayers[MAX_PLAYERS];
	new iCount;

	switch(get_member(pOwner, m_iTeam)) {
		case TEAM_TERRORIST: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"CT"
			);
		}
		case TEAM_CT: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"TERRORIST"
			);
		}
		default: {
			return;
		}
	}

	for(new i, id; i < iCount; i++) {
		id = iPlayers[i];

		get_entvar(id, var_origin, flVecOriginEnd);

		if(get_distance_f(flVecOriginStart, flVecOriginEnd) < 300.0) {
			ExecuteHamB(Ham_TakeDamage, id, eEnt, pOwner, 500.0, DMG_BURN);
		}
	}
}

public RG_CBasePlayer_ResetMaxSpeed_Pre(pPlayer) {
	if(!is_user_connected(pPlayer) && g_iModeCopter[pPlayer] == Mode_Control) {
		set_entvar(pPlayer, var_maxspeed, -1.0);
		return HC_SUPERCEDE;
	}

	return HC_CONTINUE;
}

public RG_CBasePlayer_Jump_Pre(pPlayer) {
	if(!is_user_alive(pPlayer) || g_iModeCopter[pPlayer] != Mode_Control || is_nullent(g_eEntCopter[pPlayer])) {
		return;
	}

	new Float: flVecVelocity[3];
	get_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);
	flVecVelocity[2] += 100.0;
	set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);

	set_entvar(pPlayer, var_oldbuttons, get_entvar(pPlayer, var_oldbuttons) | IN_JUMP);
}

public RG_CBasePlayer_Duck_Pre(pPlayer) {
	if(!is_user_alive(pPlayer) || g_iModeCopter[pPlayer] != Mode_Control || is_nullent(g_eEntCopter[pPlayer])) {
		return;
	}

	new Float: flVecVelocity[3];
	get_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);
	flVecVelocity[2] -= 100.0;
	set_entvar(g_eEntCopter[pPlayer], var_velocity, flVecVelocity);

	set_entvar(pPlayer, var_oldbuttons, get_entvar(pPlayer, var_oldbuttons) | IN_DUCK);
}

public CBasePlayerWeapon_DefaultDeploy_Post(iItem, const szViewModel[], const szWeaponModel[], iAnim, const szAnimExt[], skiplocal)
{
	if(is_nullent(iItem)) {
		return;
	}

	new pPlayer = get_member(iItem, m_pPlayer);

	if(!is_user_alive(pPlayer) || g_iModeCopter[pPlayer] != Mode_Control) {
		return;
	}

	set_member(pPlayer, m_flNextAttack, get_gametime());
}

public Ham_TakeDamage_Copter_Pre(eEnt, iInflictor, pAttacker, Float: flDamage, bitDamageType) {
	if(is_nullent(eEnt) || get_entvar(eEnt, var_impulse) != COPTER_IMPULSE) {
		return;
	}

	if(!is_user_connected(pAttacker)) {
		return;
	}

	new pOwner = get_entvar(eEnt, var_euser1);

	if(pOwner == pAttacker || !is_user_connected(pOwner) || get_member(pAttacker, m_iTeam) != get_member(pOwner, m_iTeam)) {
		return;
	}

	SetHamParamFloat(4, 0.0);
}

public Ham_Killed_Copter_Pre(eEnt, pAttacker, iCorpse) {
	if(is_nullent(eEnt) || get_entvar(eEnt, var_impulse) != COPTER_IMPULSE) {
		return HAM_IGNORED;
	}

	copter_explode(eEnt);
	_remove_ent(eEnt);

	new pOwner = get_entvar(eEnt, var_euser1);

	if(is_user_connected(pOwner)) {
		g_eEntCopter[pOwner] = NULLENT;

		if(is_user_alive(pOwner) && g_iModeCopter[pOwner] == Mode_Control) {
			engset_view(pOwner, pOwner);
		}

		player_close_menu_copter(pOwner);

		g_eEntCopter[pOwner] = NULLENT;
		g_iModeCopter[pOwner] = Mode_Draw;

		if(pOwner == pAttacker) {
			client_print_color(pOwner, print_team_default, "Вы взорвали свой ^3коптер");
		}
		else if(is_user_connected(pAttacker)) {
			client_print_color(pOwner, print_team_default, "Ваш^3 коптер ^1уничтожил^4 %n", pAttacker);
		}
		else {
			client_print_color(pOwner, print_team_default, "Ваш^3 коптер ^1уничтожен");
		}
	}

	return HAM_SUPERCEDE;
}

public load_config() {
	new const szConfigPath[] = "addons/amxmodx/configs/copter_settings.cfg";

	if(!file_exists(szConfigPath)) {
		set_fail_state("Конфиг ^"%s^" не загружен. Плагин остановлен", szConfigPath);
		return;
	}

	new INIParser: iParser = INI_CreateParser();

	INI_SetReaders(iParser, "INI_ReadKeyValue");
	INI_ParseFile(iParser, szConfigPath);

	INI_DestroyParser(iParser);
}

public bool: INI_ReadKeyValue(INIParser: iParser, const szKey[], const szValue[]) {
	if(szKey[0] == EOS) {
		return true;
	}

	new szString[128];
	format(szString, charsmax(szString), "%s", szValue);
	trim(szString);

	if(equal(szKey, "copter_cost")) {
		g_iCopterCost = str_to_num(szString);
	}
	else if(equal(szKey, "copter_health")) {
		g_flCopterHealth = str_to_float(szString);
	}
	else if(equal(szKey, "copter_damage")) {
		g_flCopterDamage = str_to_float(szString);
	}

	return true;
}

#if defined FULLPACK_ON
public Fwd_AddToFullPack_Post(es, e, ent, host, flags, player, pSet)
{
	if(!player || !is_user_connected(e) || g_iModeCopter[e] != Mode_Control)
		return;

	set_es(es, ES_Sequence, 62); // ref_aim_c4
	set_es(es, ES_GaitSequence, 14); // ref_shoot_carbine
	set_es(es, ES_WeaponModel, NULL_STRING);
	set_es(es, ES_Angles, NULL_VECTOR);
}
#endif
public _remove_ent(eEnt) {
	if(!is_nullent(eEnt)) {
		rg_remove_entity(eEnt);
	}
}

public player_close_menu_copter(pPlayer) {
	new iIndexMenu, iIndexMenuNew;
	if(player_menu_info(pPlayer, iIndexMenu, iIndexMenuNew)) {
		if(g_iMenuCopter[pPlayer] == iIndexMenuNew) {
			menu_cancel(pPlayer);
			show_menu(pPlayer, 0, "^n", 1);
		}
	}
}

// thx Retro-kolt Lincoln
stock CREATE_BEAMENTPOINT(iEntity, Float: flVecOrigin[3], pSprite, iStartFrame = 0, iFrameRate = 0, iLife, iWidth, iAmplitude = 0, iRed, iGreen, iBlue, iBrightness, iScrollSpeed = 0, iReliable = 0)
{
	message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMENTPOINT);
	write_short(iEntity);
	write_coord_f(flVecOrigin[0]);
	write_coord_f(flVecOrigin[1]);
	write_coord_f(flVecOrigin[2]);
	write_short(pSprite); // Индекс спрайта из прекеша (index of precached sprite)
	write_byte(iStartFrame);
	write_byte(iFrameRate); // 0.1's
	write_byte(iLife); // 0.1's
	write_byte(iWidth);
	write_byte(iAmplitude); // 0.01's
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	write_byte(iScrollSpeed); // 0.1's
	message_end();
}

stock CREATE_BEAMPOINTS(Float:fStartOrigin[3], Float:fEndOrigin[3], pSprite, iStartFrame = 0, iFrameRate = 0, iLife, iWidth, iAmplitude = 0, iRed, iGreen, iBlue, iBrightness, iScrollSpeed = 0, iReliable = 0) {
	message_begin(iReliable ? MSG_ALL : MSG_BROADCAST, SVC_TEMPENTITY);
	write_byte(TE_BEAMPOINTS);
	write_coord_f(fStartOrigin[0]);
	write_coord_f(fStartOrigin[1]);
	write_coord_f(fStartOrigin[2]);
	write_coord_f(fEndOrigin[0]);
	write_coord_f(fEndOrigin[1]);
	write_coord_f(fEndOrigin[2]);
	write_short(pSprite); // Индекс спрайта из прекеша (index of precached sprite)
	write_byte(iStartFrame);
	write_byte(iFrameRate); // 0.1's
	write_byte(iLife); // 0.1's
	write_byte(iWidth);
	write_byte(iAmplitude); // 0.01's
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	write_byte(iScrollSpeed); // 0.1's
	message_end();
}

// thx bizon
stock get_origin_aiming_ent(eEnt, Float: flVecDest[3])
{
	static Float: flVecOrigin[3];

	get_entvar(eEnt, var_origin, flVecOrigin);
	get_entvar(eEnt, var_angles, flVecDest);

	engfunc(EngFunc_MakeVectors, flVecDest);
	global_get(glb_v_forward, flVecDest);

	xs_vec_mul_scalar(flVecDest, 8192.0, flVecDest);
	xs_vec_add(flVecOrigin, flVecDest, flVecDest);

	engfunc(EngFunc_TraceLine, flVecOrigin, flVecDest, DONT_IGNORE_MONSTERS, eEnt, 0);

	get_tr2(0, TR_vecEndPos, flVecDest);
	return get_tr2(0, TR_pHit);
}

stock get_player_origin_front(pPlayer, Float: vecOriginEnd[3], Float: flDist)
{
	new Float: vecData[3];

	get_entvar(pPlayer, var_origin, vecData);
	get_entvar(pPlayer, var_v_angle, vecOriginEnd);

	vecOriginEnd[0] = 0.0;

	engfunc(EngFunc_MakeVectors, vecOriginEnd);
	global_get(glb_v_forward, vecOriginEnd);

	xs_vec_mul_scalar(vecOriginEnd, flDist, vecOriginEnd);
	xs_vec_add(vecData, vecOriginEnd, vecOriginEnd);

	engfunc(EngFunc_TraceLine, vecData, vecOriginEnd, DONT_IGNORE_MONSTERS, pPlayer, 0);
	get_tr2(0, TR_vecEndPos, vecOriginEnd);
}

stock find_range_enemy(pPlayer, eEnt) {
	new iPlayers[MAX_PLAYERS];
	new iCount;
	new pVictim = NULLENT;

	switch(get_member(pPlayer, m_iTeam)) {
		case TEAM_TERRORIST: {
			get_players_ex(iPlayers, iCount,
			GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"CT"
			);
		}
		case TEAM_CT: {
			get_players_ex(iPlayers, iCount,
				GetPlayers_ExcludeDead | GetPlayers_MatchTeam | GetPlayers_ExcludeHLTV | GetPlayers_IncludeConnecting,
				"TERRORIST"
			);
		}
		default: {
			return pVictim;
		}
	}

	new Float: flVecOriginCopter[3], Float: flVecOriginPlayer[3];
	get_entvar(eEnt, var_origin, flVecOriginCopter);

	for(new i, id, Float: flMinDist = 9999.0, Float: flDist, Float: fFlFraction; i < iCount; i++) {
		id = iPlayers[i];

		get_entvar(id, var_origin, flVecOriginPlayer);

		engfunc(EngFunc_TraceLine, flVecOriginCopter, flVecOriginPlayer, IGNORE_MONSTERS, eEnt, 0);
		get_tr2(0, TR_flFraction, fFlFraction);

		if(fFlFraction != 1.0 && get_tr2(0, TR_pHit) != eEnt)
			continue;

		flDist = get_distance_f(flVecOriginCopter, flVecOriginPlayer);

		if(flDist < flMinDist) {
			flMinDist = flDist;
			pVictim = id;
		}
	}

	return pVictim;
}

stock bool: is_hull_vacant(Float: flVecOrigin[3], iHull, eEnt)
{
	engfunc(EngFunc_TraceHull, flVecOrigin, flVecOrigin, DONT_IGNORE_MONSTERS, iHull, eEnt, 0);
 
	return !get_tr2(0, TR_StartSolid) && !get_tr2(0, TR_AllSolid) && get_tr2(0, TR_InOpen);
}
Версия	Дата выхода	Размер	Скачиваний	Скачать
0.1	Вчера, 21:04	221.35 КБ	0	Copter.zip
Кто сейчас на конференции

Зарегистрированные пользователи: Ahrefs [Bot], Semrush [Bot]
Место свободно
Здесь вы сможете купить рекламу на данном форуме
Стоимость за 1 день 12 ₽
Copter | Коптер

Версия: 0.1 21.12.2025 21:04

Кто сейчас на конференции
