Код: Выделить всё

const SIM_STEPS = 15; // Кол-во шагов для просчёта траектории
const Float: SIM_DELTA = 0.1; // Шаг времени просчёта (15 * 0.1 = 1.5 секунды полета)
const Float: THROW_SPEED = 600.0; // Стартовая сила полёта

new g_iColorHegrenade[] = { 255, 64, 64 }; // Цвет RGB для hegrenade
new g_iColorFlashbang[] = { 0, 220, 255 }; // Цвет RGB для flashbang
new g_iColorSmokegrenade[] = { 50, 255, 50 }; // Цвет RGB для smokegrenade

Код: Выделить всё

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

new const g_szVerionPlugin[] = "0.1";

#define linux_diff_weapon	4
#define m_iId 			43
#define m_pPlayer		41

const SIM_STEPS = 15; // Кол-во шагов для просчёта траектории
const Float: SIM_DELTA = 0.1; // Шаг времени просчёта (15 * 0.1 = 1.5 секунды полета)
const Float: THROW_SPEED = 600.0; // Стартовая сила полёта

new g_iColorHegrenade[] = { 255, 64, 64 }; // Цвет RGB для hegrenade
new g_iColorFlashbang[] = { 0, 220, 255 }; // Цвет RGB для flashbang
new g_iColorSmokegrenade[] = { 50, 255, 50 }; // Цвет RGB для smokegrenade

new g_SpriteIndex;
new g_pCvarGravity;

public plugin_init() {
	register_plugin("Grenade Trajectory", g_szVerionPlugin, "Kurtis");

	RegisterHam(Ham_Item_PreFrame, "weapon_hegrenade", "fwHam_Grenade_PreFrame");
	RegisterHam(Ham_Item_PreFrame, "weapon_flashbang", "fwHam_Grenade_PreFrame");
	RegisterHam(Ham_Item_PreFrame, "weapon_smokegrenade", "fwHam_Grenade_PreFrame");

	bind_pcvar_num(get_cvar_pointer("sv_gravity"), g_pCvarGravity);
}

public plugin_precache() {
	g_SpriteIndex = precache_model("sprites/laserbeam.spr");
}

public fwHam_Grenade_PreFrame(iItem) {
	if(!pev_valid(iItem)) {
		return;
	}

	new pPlayer = get_pdata_cbase(iItem, m_pPlayer, linux_diff_weapon);

	if(!is_user_alive(pPlayer) || ~pev(pPlayer, pev_button) & IN_ATTACK) {
		return;
	}

	new Float: flGameTime = get_gametime();
	static Float: flNextTime[MAX_PLAYERS+1];

	if(flGameTime < flNextTime[pPlayer]) {
		return
	}

	flNextTime[pPlayer] = flGameTime + 0.1; 
	DrawGrenadeTrajectory(pPlayer, get_pdata_int(iItem, m_iId, linux_diff_weapon));
}

public DrawGrenadeTrajectory(pPlayer, w_iId) {
	new Float: flVecOrigin[3];
	ExecuteHam(Ham_Player_GetGunPosition, pPlayer, flVecOrigin);

	new Float: flVecAngle[3];
	pev(pPlayer, pev_v_angle, flVecAngle);
	flVecAngle[0] -= 10.0; 

	new Float: vForward[3];
	angle_vector(flVecAngle, ANGLEVECTOR_FORWARD, vForward);

	new Float: flVecVelocity[3];
	flVecVelocity[0] = vForward[0] * THROW_SPEED;
	flVecVelocity[1] = vForward[1] * THROW_SPEED;
	flVecVelocity[2] = vForward[2] * THROW_SPEED;

	new Float: flVecUserVelocity[3];
	pev(pPlayer, pev_velocity, flVecUserVelocity);

	new Float: flForwardSpeed = xs_vec_dot(flVecUserVelocity, vForward);

	flVecVelocity[0] += vForward[0] * flForwardSpeed * 1.25;
	flVecVelocity[1] += vForward[1] * flForwardSpeed * 1.25;
	flVecVelocity[2] += vForward[2] * flForwardSpeed * 1.25;

	new Float: flVecOriginPos[3], Float: flVecOriginPosNext[3];
	xs_vec_copy(flVecOrigin, flVecOriginPos);

	new Float: flGrenadeGravity = float(g_pCvarGravity) * 0.5;
	new iTraceHandle = create_tr2();

	for(new i; i < SIM_STEPS; i++) {
		flVecOriginPosNext[0] = flVecOriginPos[0] + flVecVelocity[0] * SIM_DELTA;
		flVecOriginPosNext[1] = flVecOriginPos[1] + flVecVelocity[1] * SIM_DELTA;
		flVecOriginPosNext[2] = flVecOriginPos[2] + flVecVelocity[2] * SIM_DELTA;

		flVecVelocity[2] -= flGrenadeGravity * SIM_DELTA;

		engfunc(EngFunc_TraceLine, flVecOriginPos, flVecOriginPosNext, IGNORE_MONSTERS, pPlayer, iTraceHandle);

		new Float: flFraction;
		get_tr2(iTraceHandle, TR_flFraction, flFraction);

		if(flFraction < 1.0) {
			get_tr2(iTraceHandle, TR_vecEndPos, flVecOriginPosNext);
			_DrawPoint(pPlayer, flVecOriginPos, flVecOriginPosNext, w_iId);
			break; 
		}

		_DrawPoint(pPlayer, flVecOriginPos, flVecOriginPosNext, w_iId);
		xs_vec_copy(flVecOriginPosNext, flVecOriginPos);
	}

	free_tr2(iTraceHandle);
}

public _DrawPoint(pPlayer, Float: flVecOriginStart[3], Float: flVecOriginEnd[3], w_iId) {
	new iRed, iGreen, iBlue;

	switch(w_iId) {
		case CSW_HEGRENADE: {
			iRed = g_iColorHegrenade[0];
			iGreen = g_iColorHegrenade[1]; 
			iBlue = g_iColorHegrenade[2]; 
		}

		case CSW_FLASHBANG: {
			iRed = g_iColorFlashbang[0];
			iGreen = g_iColorFlashbang[1]; 
			iBlue = g_iColorFlashbang[2]; 
		}

		case CSW_SMOKEGRENADE: {
			iRed = g_iColorSmokegrenade[0];
			iGreen = g_iColorSmokegrenade[1]; 
			iBlue = g_iColorSmokegrenade[2];  
		}
	}

	_create_beampoints(pPlayer, flVecOriginStart, flVecOriginEnd, g_SpriteIndex, 0, 0, 2, 6, 0, iRed, iGreen, iBlue, 220, 0);
}

public _create_beampoints(
			pPlayer,
			Float: flVecOriginStart[3],
			Float: flVecOriginEnd[3],
			iSprite,
			iStartFrame,
			iFrameRate,
			iLifeTime,
			iLine,
			iNoise,
			iRed,
			iGreen,
			iBlue,
			iBrightness,
			iScrollSpeed
		) {

	message_begin(MSG_ONE_UNRELIABLE, SVC_TEMPENTITY, _, pPlayer);
	write_byte(TE_BEAMPOINTS);
	write_coord_f(flVecOriginStart[0]);
	write_coord_f(flVecOriginStart[1]);
	write_coord_f(flVecOriginStart[2]);
	write_coord_f(flVecOriginEnd[0]);
	write_coord_f(flVecOriginEnd[1]);
	write_coord_f(flVecOriginEnd[2]);
	write_short(iSprite);
	write_byte(iStartFrame);
	write_byte(iFrameRate);
	write_byte(iLifeTime);
	write_byte(iLine);
	write_byte(iNoise);
	write_byte(iRed);
	write_byte(iGreen);
	write_byte(iBlue);
	write_byte(iBrightness);
	write_byte(iScrollSpeed);
	message_end();
}

Код: Выделить всё

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>